mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-05 04:50:03 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
229 lines
2.9 KiB
Scheme
229 lines
2.9 KiB
Scheme
(line_comment) @comment @spell
|
|
|
|
[
|
|
(container_doc_comment)
|
|
(doc_comment)
|
|
] @comment.documentation @spell
|
|
|
|
[
|
|
variable: (IDENTIFIER)
|
|
variable_type_function: (IDENTIFIER)
|
|
] @variable
|
|
|
|
parameter: (IDENTIFIER) @variable.parameter
|
|
|
|
[
|
|
field_member: (IDENTIFIER)
|
|
field_access: (IDENTIFIER)
|
|
] @variable.member
|
|
|
|
;; assume TitleCase is a type
|
|
(
|
|
[
|
|
variable_type_function: (IDENTIFIER)
|
|
field_access: (IDENTIFIER)
|
|
parameter: (IDENTIFIER)
|
|
] @type
|
|
(#lua-match? @type "^%u([%l]+[%u%l%d]*)*$")
|
|
)
|
|
;; assume camelCase is a function
|
|
(
|
|
[
|
|
variable_type_function: (IDENTIFIER)
|
|
field_access: (IDENTIFIER)
|
|
parameter: (IDENTIFIER)
|
|
] @function
|
|
(#lua-match? @function "^%l+([%u][%l%d]*)+$")
|
|
)
|
|
|
|
;; assume all CAPS_1 is a constant
|
|
(
|
|
[
|
|
variable_type_function: (IDENTIFIER)
|
|
field_access: (IDENTIFIER)
|
|
] @constant
|
|
(#lua-match? @constant "^%u[%u%d_]+$")
|
|
)
|
|
|
|
function: (IDENTIFIER) @function
|
|
function_call: (IDENTIFIER) @function.call
|
|
|
|
exception: "!" @keyword.exception
|
|
|
|
(
|
|
(IDENTIFIER) @variable.builtin
|
|
(#eq? @variable.builtin "_")
|
|
)
|
|
|
|
(PtrTypeStart "c" @variable.builtin)
|
|
|
|
(
|
|
(ContainerDeclType
|
|
[
|
|
(ErrorUnionExpr)
|
|
"enum"
|
|
]
|
|
)
|
|
(ContainerField (IDENTIFIER) @constant)
|
|
)
|
|
|
|
field_constant: (IDENTIFIER) @constant
|
|
|
|
(BUILTINIDENTIFIER) @function.builtin
|
|
|
|
((BUILTINIDENTIFIER) @keyword.import
|
|
(#any-of? @keyword.import "@import" "@cImport"))
|
|
|
|
(INTEGER) @number
|
|
|
|
(FLOAT) @number.float
|
|
|
|
[
|
|
"true"
|
|
"false"
|
|
] @boolean
|
|
|
|
[
|
|
(LINESTRING)
|
|
(STRINGLITERALSINGLE)
|
|
] @string @spell
|
|
|
|
(CHAR_LITERAL) @character
|
|
(EscapeSequence) @string.escape
|
|
(FormatSequence) @string.special
|
|
|
|
(BreakLabel (IDENTIFIER) @label)
|
|
(BlockLabel (IDENTIFIER) @label)
|
|
|
|
[
|
|
"asm"
|
|
"defer"
|
|
"errdefer"
|
|
"test"
|
|
"struct"
|
|
"union"
|
|
"enum"
|
|
"opaque"
|
|
"error"
|
|
] @keyword
|
|
|
|
[
|
|
"async"
|
|
"await"
|
|
"suspend"
|
|
"nosuspend"
|
|
"resume"
|
|
] @keyword.coroutine
|
|
|
|
[
|
|
"fn"
|
|
] @keyword.function
|
|
|
|
[
|
|
"and"
|
|
"or"
|
|
"orelse"
|
|
] @keyword.operator
|
|
|
|
[
|
|
"return"
|
|
] @keyword.return
|
|
|
|
[
|
|
"if"
|
|
"else"
|
|
"switch"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
"for"
|
|
"while"
|
|
"break"
|
|
"continue"
|
|
] @keyword.repeat
|
|
|
|
[
|
|
"usingnamespace"
|
|
] @keyword.import
|
|
|
|
[
|
|
"try"
|
|
"catch"
|
|
] @keyword.exception
|
|
|
|
[
|
|
"anytype"
|
|
(BuildinTypeExpr)
|
|
] @type.builtin
|
|
|
|
[
|
|
"const"
|
|
"var"
|
|
"volatile"
|
|
"allowzero"
|
|
"noalias"
|
|
] @type.qualifier
|
|
|
|
[
|
|
"addrspace"
|
|
"align"
|
|
"callconv"
|
|
"linksection"
|
|
] @keyword.storage
|
|
|
|
[
|
|
"comptime"
|
|
"export"
|
|
"extern"
|
|
"inline"
|
|
"noinline"
|
|
"packed"
|
|
"pub"
|
|
"threadlocal"
|
|
] @attribute
|
|
|
|
[
|
|
"null"
|
|
"unreachable"
|
|
"undefined"
|
|
] @constant.builtin
|
|
|
|
[
|
|
(CompareOp)
|
|
(BitwiseOp)
|
|
(BitShiftOp)
|
|
(AdditionOp)
|
|
(AssignOp)
|
|
(MultiplyOp)
|
|
(PrefixOp)
|
|
"*"
|
|
"**"
|
|
"->"
|
|
".?"
|
|
".*"
|
|
"?"
|
|
] @operator
|
|
|
|
[
|
|
";"
|
|
"."
|
|
","
|
|
":"
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
".."
|
|
"..."
|
|
] @punctuation.special
|
|
|
|
[
|
|
"["
|
|
"]"
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
(Payload "|")
|
|
(PtrPayload "|")
|
|
(PtrIndexPayload "|")
|
|
] @punctuation.bracket
|