mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-08 06:20:01 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
121 lines
1.8 KiB
Scheme
121 lines
1.8 KiB
Scheme
; Built-ins {{{
|
|
((function_call
|
|
function: (identifier) @function.builtin)
|
|
(#any-of? @function.builtin "chr" "concat" "exit" "flush" "getchar" "not" "ord" "print" "print_err" "print_int" "size" "strcmp" "streq" "substring")
|
|
; FIXME: not supported by neovim
|
|
; (#is-not? local)
|
|
)
|
|
|
|
((type_identifier) @type.builtin
|
|
(#any-of? @type.builtin "int" "string" "Object")
|
|
; FIXME: not supported by neovim
|
|
; (#is-not? local)
|
|
)
|
|
|
|
((identifier) @variable.builtin
|
|
(#eq? @variable.builtin "self")
|
|
; FIXME: not supported by neovim
|
|
; (#is-not? local)
|
|
)
|
|
; }}}
|
|
|
|
; Keywords {{{
|
|
[
|
|
"function"
|
|
"primitive"
|
|
"method"
|
|
] @keyword.function
|
|
|
|
[
|
|
"do"
|
|
"for"
|
|
"to"
|
|
"while"
|
|
] @keyword.repeat
|
|
|
|
"new" @keyword.operator
|
|
|
|
"import" @keyword.import
|
|
|
|
[
|
|
"array"
|
|
(break_expression)
|
|
"else"
|
|
"end"
|
|
"if"
|
|
"in"
|
|
"let"
|
|
"of"
|
|
"then"
|
|
"type"
|
|
"var"
|
|
|
|
"class"
|
|
"extends"
|
|
|
|
"_cast"
|
|
"_chunks"
|
|
"_exp"
|
|
"_lvalue"
|
|
"_namety"
|
|
] @keyword
|
|
; }}}
|
|
|
|
; Operators {{{
|
|
(operator) @operator
|
|
|
|
[
|
|
","
|
|
";"
|
|
":"
|
|
"."
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
; }}}
|
|
|
|
; Functions and methods {{{
|
|
(function_call
|
|
function: (identifier) @function)
|
|
(function_declaration
|
|
name: (identifier) @function)
|
|
(primitive_declaration
|
|
name: (identifier) @function)
|
|
|
|
(method_call
|
|
method: (identifier) @function.method)
|
|
(method_declaration
|
|
name: (identifier) @function.method)
|
|
|
|
(parameters
|
|
name: (identifier) @variable.parameter)
|
|
; }}}
|
|
|
|
; Declarations {{{
|
|
(import_declaration
|
|
file: (string_literal) @string.special.path)
|
|
; }}}
|
|
|
|
; Literals {{{
|
|
(nil_literal) @constant.builtin
|
|
(integer_literal) @number
|
|
(string_literal) @string
|
|
(escape_sequence) @string.escape
|
|
; }}}
|
|
|
|
; Misc {{{
|
|
(comment) @comment @spell
|
|
|
|
(type_identifier) @type
|
|
(field_identifier) @property
|
|
(identifier) @variable
|
|
; }}}
|
|
|
|
; vim: sw=2 foldmethod=marker
|