mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-08 06:20:01 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
226 lines
3.1 KiB
Scheme
226 lines
3.1 KiB
Scheme
; Variables
|
|
|
|
((identifier) @variable
|
|
(#set! "priority" 95))
|
|
|
|
; Includes
|
|
|
|
[
|
|
"include"
|
|
"cpp_include"
|
|
] @keyword.import
|
|
|
|
; Function
|
|
|
|
(function_definition
|
|
(identifier) @function)
|
|
|
|
; Fields
|
|
|
|
(field (identifier) @variable.member)
|
|
|
|
; Parameters
|
|
|
|
(function_definition
|
|
(parameters
|
|
(parameter (identifier) @variable.parameter)))
|
|
|
|
(throws
|
|
(parameters
|
|
(parameter (identifier) @variable.parameter)))
|
|
|
|
; Types
|
|
|
|
(typedef_identifier) @type
|
|
(struct_definition
|
|
"struct" (identifier) @type)
|
|
|
|
(union_definition
|
|
"union" (identifier) @type)
|
|
|
|
(exception_definition
|
|
"exception" (identifier) @type)
|
|
|
|
(service_definition
|
|
"service" (identifier) @type)
|
|
|
|
(interaction_definition
|
|
"interaction" (identifier) @type)
|
|
|
|
(type
|
|
type: (identifier) @type)
|
|
|
|
(definition_type
|
|
type: (identifier) @type)
|
|
|
|
((identifier) @type
|
|
(#lua-match? @type "^[_]*[A-Z]"))
|
|
|
|
; Constants
|
|
|
|
(const_definition (identifier) @constant)
|
|
((identifier) @constant
|
|
(#lua-match? @constant "^[_A-Z][A-Z0-9_]*$"))
|
|
(enum_definition "enum"
|
|
. (identifier) @type
|
|
"{" (identifier) @constant "}")
|
|
|
|
; Builtin Types
|
|
|
|
(primitive) @type.builtin
|
|
|
|
[
|
|
"list"
|
|
"map"
|
|
"set"
|
|
"sink"
|
|
"stream"
|
|
"void"
|
|
] @type.builtin
|
|
|
|
; Namespace
|
|
|
|
(namespace_declaration
|
|
(namespace_scope) @tag
|
|
[(namespace) @module (_ (identifier) @module)])
|
|
|
|
; Attributes
|
|
|
|
(annotation_definition
|
|
(annotation_identifier (identifier) @attribute))
|
|
(fb_annotation_definition
|
|
"@" @attribute (annotation_identifier (identifier) @attribute)
|
|
(identifier)? @attribute)
|
|
(namespace_uri (string) @attribute)
|
|
|
|
; Operators
|
|
|
|
[
|
|
"="
|
|
"&"
|
|
] @operator
|
|
|
|
; Exceptions
|
|
|
|
[
|
|
"throws"
|
|
] @keyword.exception
|
|
|
|
; Keywords
|
|
|
|
[
|
|
"enum"
|
|
"exception"
|
|
"extends"
|
|
"interaction"
|
|
"namespace"
|
|
"senum"
|
|
"service"
|
|
"struct"
|
|
"typedef"
|
|
"union"
|
|
"uri"
|
|
] @keyword
|
|
|
|
; Deprecated Keywords
|
|
|
|
[
|
|
"cocoa_prefix"
|
|
"cpp_namespace"
|
|
"csharp_namespace"
|
|
"delphi_namespace"
|
|
"java_package"
|
|
"perl_package"
|
|
"php_namespace"
|
|
"py_module"
|
|
"ruby_namespace"
|
|
"smalltalk_category"
|
|
"smalltalk_prefix"
|
|
"xsd_all"
|
|
"xsd_attrs"
|
|
"xsd_namespace"
|
|
"xsd_nillable"
|
|
"xsd_optional"
|
|
] @keyword
|
|
|
|
; Extended Keywords
|
|
[
|
|
"package"
|
|
"performs"
|
|
] @keyword
|
|
|
|
[
|
|
"async"
|
|
"oneway"
|
|
] @keyword.coroutine
|
|
|
|
; Qualifiers
|
|
|
|
[
|
|
"client"
|
|
"const"
|
|
"idempotent"
|
|
"optional"
|
|
"permanent"
|
|
"readonly"
|
|
"required"
|
|
"safe"
|
|
"server"
|
|
"stateful"
|
|
"transient"
|
|
] @type.qualifier
|
|
|
|
; Literals
|
|
|
|
(string) @string
|
|
|
|
(escape_sequence) @string.escape
|
|
|
|
(namespace_uri
|
|
(string) @string.special.url)
|
|
|
|
(number) @number
|
|
|
|
(double) @number.float
|
|
|
|
(boolean) @boolean
|
|
|
|
; Typedefs
|
|
|
|
(typedef_identifier) @type.definition
|
|
|
|
; Punctuation
|
|
|
|
[
|
|
"*"
|
|
] @punctuation.special
|
|
|
|
["{" "}"] @punctuation.bracket
|
|
|
|
["(" ")"] @punctuation.bracket
|
|
|
|
["[" "]"] @punctuation.bracket
|
|
|
|
["<" ">"] @punctuation.bracket
|
|
|
|
[
|
|
"."
|
|
","
|
|
";"
|
|
":"
|
|
] @punctuation.delimiter
|
|
|
|
; Comments
|
|
|
|
(comment) @comment @spell
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///[^/]"))
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///$"))
|
|
|
|
((comment) @keyword.directive
|
|
(#lua-match? @keyword.directive "#!.*"))
|