mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 22:10:01 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
189 lines
3.8 KiB
Scheme
189 lines
3.8 KiB
Scheme
[ "." ";" ":" "," ] @punctuation.delimiter
|
|
; TODO: "\\(" ")" in interpolations should be @punctuation.special
|
|
[ "\\(" "(" ")" "[" "]" "{" "}"] @punctuation.bracket
|
|
|
|
; Identifiers
|
|
(attribute) @variable
|
|
(type_identifier) @type
|
|
(self_expression) @variable.builtin
|
|
|
|
; Declarations
|
|
"func" @keyword.function
|
|
|
|
[
|
|
(visibility_modifier)
|
|
(member_modifier)
|
|
(function_modifier)
|
|
(property_modifier)
|
|
(parameter_modifier)
|
|
(inheritance_modifier)
|
|
(mutation_modifier)
|
|
] @type.qualifier
|
|
|
|
(function_declaration (simple_identifier) @function.method)
|
|
(function_declaration ["init" @constructor])
|
|
(throws) @keyword
|
|
(where_keyword) @keyword
|
|
(parameter external_name: (simple_identifier) @variable.parameter)
|
|
(parameter name: (simple_identifier) @variable.parameter)
|
|
(type_parameter (type_identifier) @variable.parameter)
|
|
(inheritance_constraint (identifier (simple_identifier) @variable.parameter))
|
|
(equality_constraint (identifier (simple_identifier) @variable.parameter))
|
|
(pattern bound_identifier: (simple_identifier)) @variable
|
|
|
|
[
|
|
"typealias"
|
|
"struct"
|
|
"class"
|
|
"actor"
|
|
"enum"
|
|
"protocol"
|
|
"extension"
|
|
"indirect"
|
|
"nonisolated"
|
|
"override"
|
|
"convenience"
|
|
"required"
|
|
"some"
|
|
] @keyword
|
|
|
|
[
|
|
"async"
|
|
"await"
|
|
] @keyword.coroutine
|
|
|
|
[
|
|
(getter_specifier)
|
|
(setter_specifier)
|
|
(modify_specifier)
|
|
] @keyword
|
|
|
|
(class_body (property_declaration (pattern (simple_identifier) @property)))
|
|
(protocol_property_declaration (pattern (simple_identifier) @property))
|
|
(navigation_expression
|
|
(navigation_suffix (simple_identifier) @property))
|
|
(value_argument
|
|
name: (value_argument_label) @property)
|
|
|
|
(import_declaration ["import" @keyword.import])
|
|
|
|
(enum_entry ["case" @keyword])
|
|
|
|
; Function calls
|
|
(call_expression (simple_identifier) @function.call) ; foo()
|
|
(call_expression ; foo.bar.baz(): highlight the baz()
|
|
(navigation_expression
|
|
(navigation_suffix (simple_identifier) @function.call)))
|
|
(call_expression
|
|
(prefix_expression (simple_identifier) @function.call)) ; .foo()
|
|
((navigation_expression
|
|
(simple_identifier) @type) ; SomeType.method(): highlight SomeType as a type
|
|
(#lua-match? @type "^[A-Z]"))
|
|
|
|
(directive) @function.macro
|
|
(diagnostic) @function.macro
|
|
|
|
; Statements
|
|
(for_statement ["for" @keyword.repeat])
|
|
(for_statement ["in" @keyword.repeat])
|
|
(for_statement (pattern) @variable)
|
|
(else) @keyword
|
|
(as_operator) @keyword
|
|
|
|
["while" "repeat" "continue" "break"] @keyword.repeat
|
|
|
|
["let" "var"] @keyword
|
|
|
|
(guard_statement ["guard" @keyword.conditional])
|
|
(if_statement ["if" @keyword.conditional])
|
|
(switch_statement ["switch" @keyword.conditional])
|
|
(switch_entry ["case" @keyword])
|
|
(switch_entry ["fallthrough" @keyword])
|
|
(switch_entry (default_keyword) @keyword)
|
|
"return" @keyword.return
|
|
(ternary_expression
|
|
["?" ":"] @keyword.conditional)
|
|
|
|
["do" (throw_keyword) (catch_keyword)] @keyword
|
|
|
|
(statement_label) @label
|
|
|
|
; Comments
|
|
[
|
|
(comment)
|
|
(multiline_comment)
|
|
] @comment @spell
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///[^/]"))
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///$"))
|
|
|
|
((multiline_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
|
|
|
|
; String literals
|
|
(line_str_text) @string
|
|
(str_escaped_char) @string
|
|
(multi_line_str_text) @string
|
|
(raw_str_part) @string
|
|
(raw_str_end_part) @string
|
|
(raw_str_interpolation_start) @punctuation.special
|
|
["\"" "\"\"\""] @string
|
|
|
|
; Lambda literals
|
|
(lambda_literal ["in" @keyword.operator])
|
|
|
|
; Basic literals
|
|
[
|
|
(integer_literal)
|
|
(hex_literal)
|
|
(oct_literal)
|
|
(bin_literal)
|
|
] @number
|
|
(real_literal) @number.float
|
|
(boolean_literal) @boolean
|
|
"nil" @constant.builtin
|
|
|
|
; Regex literals
|
|
(regex_literal) @string.regexp
|
|
|
|
; Operators
|
|
(custom_operator) @operator
|
|
[
|
|
"try"
|
|
"try?"
|
|
"try!"
|
|
"+"
|
|
"-"
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"="
|
|
"+="
|
|
"-="
|
|
"*="
|
|
"/="
|
|
"<"
|
|
">"
|
|
"<="
|
|
">="
|
|
"++"
|
|
"--"
|
|
"&"
|
|
"~"
|
|
"%="
|
|
"!="
|
|
"!=="
|
|
"=="
|
|
"==="
|
|
"??"
|
|
|
|
"->"
|
|
|
|
"..<"
|
|
"..."
|
|
(bang)
|
|
] @operator
|
|
|