mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-06 05:20:00 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
260 lines
4.1 KiB
Scheme
260 lines
4.1 KiB
Scheme
; Pragma
|
|
|
|
[
|
|
"pragma"
|
|
"solidity"
|
|
] @keyword.directive
|
|
|
|
(solidity_pragma_token
|
|
"||" @string.special.symbol)
|
|
(solidity_pragma_token
|
|
"-" @string.special.symbol)
|
|
|
|
(solidity_version_comparison_operator) @operator
|
|
|
|
(solidity_version) @string.special
|
|
|
|
; Literals
|
|
|
|
[
|
|
(string)
|
|
(yul_string_literal)
|
|
] @string
|
|
|
|
(hex_string_literal
|
|
"hex" @string.special.symbol
|
|
(_) @string)
|
|
|
|
(unicode_string_literal
|
|
"unicode" @string.special.symbol
|
|
(_) @string)
|
|
|
|
[
|
|
(number_literal)
|
|
(yul_decimal_number)
|
|
(yul_hex_number)
|
|
] @number
|
|
|
|
(yul_boolean) @boolean
|
|
|
|
; Variables
|
|
|
|
[
|
|
(identifier)
|
|
(yul_identifier)
|
|
] @variable
|
|
|
|
; Types
|
|
|
|
(type_name (identifier) @type)
|
|
(type_name (user_defined_type (identifier) @type))
|
|
(type_name "mapping" @function.builtin)
|
|
|
|
[
|
|
(primitive_type)
|
|
(number_unit)
|
|
] @type.builtin
|
|
|
|
(contract_declaration name: (identifier) @type)
|
|
(struct_declaration name: (identifier) @type)
|
|
(struct_member name: (identifier) @variable.member)
|
|
(enum_declaration name: (identifier) @type)
|
|
(emit_statement . (identifier) @type)
|
|
; Handles ContractA, ContractB in function foo() override(ContractA, contractB) {}
|
|
(override_specifier (user_defined_type) @type)
|
|
|
|
; Functions and parameters
|
|
|
|
(function_definition
|
|
name: (identifier) @function)
|
|
(modifier_definition
|
|
name: (identifier) @function)
|
|
(yul_evm_builtin) @function.builtin
|
|
|
|
; Use constructor coloring for special functions
|
|
(constructor_definition "constructor" @constructor)
|
|
|
|
(modifier_invocation (identifier) @function)
|
|
|
|
; Handles expressions like structVariable.g();
|
|
(call_expression . (member_expression (identifier) @function.method.call))
|
|
|
|
; Handles expressions like g();
|
|
(call_expression . (identifier) @function.call)
|
|
|
|
; Function parameters
|
|
(event_paramater name: (identifier) @variable.parameter)
|
|
(parameter name: (identifier) @variable.parameter)
|
|
|
|
; Yul functions
|
|
(yul_function_call function: (yul_identifier) @function.call)
|
|
|
|
; Yul function parameters
|
|
(yul_function_definition . (yul_identifier) @function (yul_identifier) @variable.parameter)
|
|
|
|
(meta_type_expression "type" @keyword)
|
|
|
|
(member_expression property: (identifier) @variable.member)
|
|
(call_struct_argument name: (identifier) @variable.member)
|
|
(struct_field_assignment name: (identifier) @variable.member)
|
|
(enum_value) @constant
|
|
|
|
; Keywords
|
|
|
|
[
|
|
"contract"
|
|
"interface"
|
|
"library"
|
|
"is"
|
|
"struct"
|
|
"enum"
|
|
"event"
|
|
"assembly"
|
|
"emit"
|
|
"override"
|
|
"modifier"
|
|
"var"
|
|
"let"
|
|
"emit"
|
|
"error"
|
|
"fallback"
|
|
"receive"
|
|
(virtual)
|
|
] @keyword
|
|
|
|
; FIXME: update grammar
|
|
; (block_statement "unchecked" @keyword)
|
|
|
|
(event_paramater "indexed" @keyword)
|
|
|
|
[
|
|
"public"
|
|
"internal"
|
|
"private"
|
|
"external"
|
|
"pure"
|
|
"view"
|
|
"payable"
|
|
(immutable)
|
|
] @type.qualifier
|
|
|
|
[
|
|
"memory"
|
|
"storage"
|
|
"calldata"
|
|
"constant"
|
|
] @keyword.storage
|
|
|
|
[
|
|
"for"
|
|
"while"
|
|
"do"
|
|
"break"
|
|
"continue"
|
|
] @keyword.repeat
|
|
|
|
[
|
|
"if"
|
|
"else"
|
|
"switch"
|
|
"case"
|
|
"default"
|
|
] @keyword.conditional
|
|
|
|
(ternary_expression
|
|
"?" @keyword.conditional.ternary
|
|
":" @keyword.conditional.ternary)
|
|
|
|
[
|
|
"try"
|
|
"catch"
|
|
"revert"
|
|
] @keyword.exception
|
|
|
|
[
|
|
"return"
|
|
"returns"
|
|
(yul_leave)
|
|
] @keyword.return
|
|
|
|
"function" @keyword.function
|
|
|
|
[
|
|
"import"
|
|
"using"
|
|
] @keyword.import
|
|
(import_directive "as" @keyword.import)
|
|
(import_directive "from" @keyword.import)
|
|
((import_directive source: (string) @string.special.path)
|
|
(#offset! @string.special.path 0 1 0 -1))
|
|
|
|
; Punctuation
|
|
|
|
[ "{" "}" ] @punctuation.bracket
|
|
|
|
[ "[" "]" ] @punctuation.bracket
|
|
|
|
[ "(" ")" ] @punctuation.bracket
|
|
|
|
[
|
|
"."
|
|
","
|
|
":"
|
|
; FIXME: update grammar
|
|
; (semicolon)
|
|
"->"
|
|
"=>"
|
|
] @punctuation.delimiter
|
|
|
|
; Operators
|
|
|
|
[
|
|
"&&"
|
|
"||"
|
|
">>"
|
|
">>>"
|
|
"<<"
|
|
"&"
|
|
"^"
|
|
"|"
|
|
"+"
|
|
"-"
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"**"
|
|
"="
|
|
"<"
|
|
"<="
|
|
"=="
|
|
"!="
|
|
"!=="
|
|
">="
|
|
">"
|
|
"!"
|
|
"~"
|
|
"-"
|
|
"+"
|
|
"++"
|
|
"--"
|
|
":="
|
|
] @operator
|
|
|
|
[
|
|
"delete"
|
|
"new"
|
|
] @keyword.operator
|
|
|
|
(import_directive "*" @character.special)
|
|
|
|
; Comments
|
|
|
|
(comment) @comment @spell
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///[^/]"))
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///$"))
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
|