mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-08 22:40:12 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
80 lines
1.5 KiB
Scheme
80 lines
1.5 KiB
Scheme
(comment) @comment @spell
|
|
|
|
"@media" @keyword
|
|
"@import" @keyword.import
|
|
"@theme" @keyword.import
|
|
|
|
(string_value) @string
|
|
[
|
|
(integer_value)
|
|
(float_value)
|
|
"0"
|
|
] @number
|
|
(boolean_value) @boolean
|
|
|
|
[
|
|
(feature_name)
|
|
(url_image_scale)
|
|
(direction)
|
|
(text_style_value)
|
|
(line_style_value)
|
|
(position_value)
|
|
(orientation_value)
|
|
(cursor_value)
|
|
"inherit"
|
|
] @keyword
|
|
|
|
|
|
(url_image "url" @function.builtin)
|
|
(gradient_image "linear-gradient" @function.builtin)
|
|
(distance_calc "calc" @function.builtin)
|
|
(rgb_color ["rgb" "rgba"] @function.builtin)
|
|
(hsl_color ["hsl" "hsla"] @function.builtin)
|
|
(hwb_color ["hwb" "hwba"] @function.builtin)
|
|
(cmyk_color "cmyk" @function.builtin)
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
] @punctuation.bracket
|
|
|
|
(distance_op) @operator
|
|
|
|
[
|
|
";"
|
|
","
|
|
":"
|
|
"."
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
(angle_unit)
|
|
(integer_distance_unit)
|
|
(float_distance_unit)
|
|
] @type
|
|
(percentage) @number
|
|
(percentage "%" @type)
|
|
|
|
[
|
|
(global_selector)
|
|
(id_selector)
|
|
] @module
|
|
|
|
(id_selector_view [ "normal" "selected" "alternate" ] @attribute)
|
|
(id_selector_state [ "normal" "urgent" "active" ] @type.qualifier)
|
|
|
|
(hex_color) @number
|
|
(hex_color "#" @punctuation.special)
|
|
(named_color (identifier) @string.special)
|
|
(named_color "/" @operator)
|
|
(reference_value "@" @punctuation.special (identifier) @variable)
|
|
(reference_value "var" @function.builtin (identifier) @variable)
|
|
(list_value (identifier) @variable)
|
|
(environ_value "$" @punctuation.special (identifier) @variable)
|
|
(environ_value "env" @function.builtin (identifier) @variable)
|
|
|
|
(property_name) @variable
|