mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 22:10:01 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
141 lines
1.7 KiB
Scheme
Executable file
141 lines
1.7 KiB
Scheme
Executable file
; highlights.scm
|
|
|
|
; Literals
|
|
(integer) @number
|
|
|
|
(float) @number.float
|
|
|
|
(complex) @number
|
|
|
|
(string) @string
|
|
(string (escape_sequence) @string.escape)
|
|
|
|
(comment) @comment @spell
|
|
|
|
((program . (comment) @keyword.directive)
|
|
(#lua-match? @keyword.directive "^#!/"))
|
|
|
|
(identifier) @variable
|
|
|
|
((dollar (identifier) @variable.builtin)
|
|
(#eq? @variable.builtin "self"))
|
|
|
|
((dollar _ (identifier) @variable.member))
|
|
|
|
; Parameters
|
|
|
|
(formal_parameters (identifier) @variable.parameter)
|
|
|
|
(formal_parameters
|
|
(default_parameter name: (identifier) @variable.parameter))
|
|
|
|
(default_argument name: (identifier) @variable.parameter)
|
|
|
|
; Namespace
|
|
|
|
(namespace_get namespace: (identifier) @module)
|
|
(namespace_get_internal namespace: (identifier) @module)
|
|
|
|
; Operators
|
|
[
|
|
"="
|
|
"<-"
|
|
"<<-"
|
|
"->"
|
|
] @operator
|
|
|
|
(unary operator: [
|
|
"-"
|
|
"+"
|
|
"!"
|
|
"~"
|
|
"?"
|
|
] @operator)
|
|
|
|
(binary operator: [
|
|
"-"
|
|
"+"
|
|
"*"
|
|
"/"
|
|
"^"
|
|
"<"
|
|
">"
|
|
"<="
|
|
">="
|
|
"=="
|
|
"!="
|
|
"||"
|
|
"|"
|
|
"&&"
|
|
"&"
|
|
":"
|
|
"~"
|
|
] @operator)
|
|
|
|
[
|
|
"|>"
|
|
(special)
|
|
] @operator
|
|
|
|
(lambda_function "\\" @operator)
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
|
|
(dollar _ "$" @operator)
|
|
|
|
(subset2
|
|
"[[" @punctuation.bracket
|
|
"]]" @punctuation.bracket)
|
|
|
|
[
|
|
(dots)
|
|
(break)
|
|
(next)
|
|
] @keyword
|
|
|
|
[
|
|
(nan)
|
|
(na)
|
|
(null)
|
|
(inf)
|
|
] @constant.builtin
|
|
|
|
[
|
|
"if"
|
|
"else"
|
|
"switch"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
"while"
|
|
"repeat"
|
|
"for"
|
|
"in"
|
|
] @keyword.repeat
|
|
|
|
[
|
|
(true)
|
|
(false)
|
|
] @boolean
|
|
|
|
"function" @keyword.function
|
|
|
|
; Functions/Methods
|
|
|
|
(call function: (identifier) @function.call)
|
|
|
|
(call
|
|
(namespace_get function: (identifier) @function.call))
|
|
|
|
(call
|
|
(namespace_get_internal function: (identifier) @function.call))
|
|
|
|
(call
|
|
function: ((dollar _ (identifier) @function.method.call)))
|