mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-02 19:46:58 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
152 lines
2.9 KiB
Scheme
152 lines
2.9 KiB
Scheme
; ----------------------------------------------------------------------------
|
|
; Literals and comments
|
|
|
|
[
|
|
(integer)
|
|
(exp_negation)
|
|
] @number
|
|
(exp_literal (number)) @number.float
|
|
(char) @character
|
|
[
|
|
(string)
|
|
(triple_quote_string)
|
|
] @string
|
|
|
|
(comment) @comment @spell
|
|
|
|
; ----------------------------------------------------------------------------
|
|
; Punctuation
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
(comma)
|
|
";"
|
|
(qualified_module) ; grabs the `.` (dot), ex: import System.IO
|
|
"."
|
|
] @punctuation.delimiter
|
|
|
|
|
|
; ----------------------------------------------------------------------------
|
|
; Keywords, operators, includes
|
|
|
|
[
|
|
"if"
|
|
"then"
|
|
"else"
|
|
"case"
|
|
"of"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
"import"
|
|
"module"
|
|
] @keyword.import
|
|
|
|
[
|
|
(operator)
|
|
(constructor_operator)
|
|
(type_operator)
|
|
(all_names)
|
|
|
|
"="
|
|
"|"
|
|
"::"
|
|
"∷"
|
|
"=>"
|
|
"⇒"
|
|
"<="
|
|
"⇐"
|
|
"->"
|
|
"→"
|
|
"<-"
|
|
"←"
|
|
"\\"
|
|
"`"
|
|
"@"
|
|
] @operator
|
|
|
|
(qualified_module (module) @constructor)
|
|
(module) @module
|
|
(qualified_type (module) @module)
|
|
(qualified_variable (module) @module)
|
|
(import (module) @module)
|
|
|
|
[
|
|
(where)
|
|
"let"
|
|
"in"
|
|
"class"
|
|
"instance"
|
|
"derive"
|
|
"foreign"
|
|
"data"
|
|
"newtype"
|
|
"type"
|
|
"as"
|
|
"hiding"
|
|
"do"
|
|
"ado"
|
|
"forall"
|
|
"∀"
|
|
"infix"
|
|
"infixl"
|
|
"infixr"
|
|
] @keyword
|
|
|
|
(class_instance "else" @keyword)
|
|
|
|
(type_role_declaration
|
|
"role" @keyword
|
|
role: (type_role) @type.qualifier)
|
|
|
|
(hole) @character.special
|
|
|
|
; `_` wildcards in if-then-else and case-of expressions,
|
|
; as well as record updates and operator sections
|
|
(wildcard) @variable.parameter
|
|
|
|
; ----------------------------------------------------------------------------
|
|
; Functions and variables
|
|
|
|
(variable) @variable
|
|
(exp_apply . (exp_name (variable) @function))
|
|
(exp_apply . (exp_name (qualified_variable (variable) @function)))
|
|
|
|
(row_field (field_name) @variable.member)
|
|
(record_field (field_name) @variable.member)
|
|
(record_accessor (variable) @variable.member)
|
|
(exp_record_access (variable) @variable.member)
|
|
|
|
(signature name: (variable) @type)
|
|
(kind_declaration (class_name) @type)
|
|
(function name: (variable) @function)
|
|
(foreign_import (variable) @function)
|
|
(class_instance (instance_name) @function)
|
|
(derive_declaration (instance_name) @function)
|
|
|
|
; true or false
|
|
((variable) @boolean
|
|
(#any-of? @boolean "true" "false"))
|
|
|
|
; The former one works for `tree-sitter highlight` but not in Helix/Kakoune.
|
|
; The latter two work in Helix (but not Kakoune) and are a good compromise between not highlighting anything at all
|
|
; as an operator and leaving it to the child nodes, and highlighting everything as an operator.
|
|
(exp_ticked (_) @operator)
|
|
(exp_ticked (exp_name (variable) @operator))
|
|
(exp_ticked (exp_name (qualified_variable (variable) @operator)))
|
|
|
|
; ----------------------------------------------------------------------------
|
|
; Types
|
|
|
|
(type) @type
|
|
|
|
(constructor) @constructor
|
|
|