mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 14:00:00 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
175 lines
3.5 KiB
Scheme
175 lines
3.5 KiB
Scheme
; Modules
|
|
;--------
|
|
|
|
[(module_name) (module_type_name)] @module
|
|
|
|
; Types
|
|
;------
|
|
|
|
(
|
|
(type_constructor) @type.builtin
|
|
(#any-of? @type.builtin
|
|
"int" "char" "bytes" "string" "float"
|
|
"bool" "unit" "exn" "array" "list" "option"
|
|
"int32" "int64" "nativeint" "format6" "lazy_t")
|
|
)
|
|
|
|
[(class_name) (class_type_name) (type_constructor)] @type
|
|
|
|
[(constructor_name) (tag)] @constructor
|
|
|
|
; Variables
|
|
;----------
|
|
|
|
[(value_name) (type_variable)] @variable
|
|
|
|
(value_pattern) @variable.parameter
|
|
|
|
; Functions
|
|
;----------
|
|
|
|
(let_binding
|
|
pattern: (value_name) @function
|
|
(parameter))
|
|
|
|
(let_binding
|
|
pattern: (value_name) @function
|
|
body: [(fun_expression) (function_expression)])
|
|
|
|
(value_specification (value_name) @function)
|
|
|
|
(external (value_name) @function)
|
|
|
|
(method_name) @function.method
|
|
|
|
; Application
|
|
;------------
|
|
|
|
(infix_expression
|
|
left: (value_path (value_name) @function.call)
|
|
operator: (concat_operator) @_operator
|
|
(#eq? @_operator "@@"))
|
|
|
|
(infix_expression
|
|
operator: (rel_operator) @_operator
|
|
right: (value_path (value_name) @function.call)
|
|
(#eq? @_operator "|>"))
|
|
|
|
(application_expression
|
|
function: (value_path (value_name) @function.call))
|
|
|
|
((value_name) @function.builtin
|
|
(#any-of? @function.builtin "raise" "raise_notrace" "failwith" "invalid_arg"))
|
|
|
|
; Properties
|
|
;-----------
|
|
|
|
[(label_name) (field_name) (instance_variable_name)] @property
|
|
|
|
; Constants
|
|
;----------
|
|
|
|
; Don't let normal parens take priority over this
|
|
((unit) @constant.builtin (#set! "priority" 105))
|
|
|
|
(boolean) @boolean
|
|
|
|
[(number) (signed_number)] @number
|
|
|
|
(character) @character
|
|
|
|
(string) @string
|
|
|
|
(quoted_string "{" @string "}" @string) @string
|
|
|
|
(escape_sequence) @string.escape
|
|
|
|
[
|
|
(conversion_specification)
|
|
(pretty_printing_indication)
|
|
] @string.special
|
|
|
|
; Keywords
|
|
;---------
|
|
|
|
[
|
|
"and" "as" "assert" "begin" "class"
|
|
"constraint" "end" "external" "in"
|
|
"inherit" "initializer" "let" "match"
|
|
"method" "module" "new" "object" "of"
|
|
"sig" "struct" "type" "val" "when" "with"
|
|
] @keyword
|
|
|
|
[
|
|
"lazy" "mutable" "nonrec"
|
|
"rec" "private" "virtual"
|
|
] @type.qualifier
|
|
|
|
["fun" "function" "functor"] @keyword.function
|
|
|
|
["if" "then" "else"] @keyword.conditional
|
|
|
|
["exception" "try"] @keyword.exception
|
|
|
|
["include" "open"] @keyword.import
|
|
|
|
["for" "to" "downto" "while" "do" "done"] @keyword.repeat
|
|
|
|
; Punctuation
|
|
;------------
|
|
|
|
(attribute ["[@" "]"] @punctuation.special)
|
|
(item_attribute ["[@@" "]"] @punctuation.special)
|
|
(floating_attribute ["[@@@" "]"] @punctuation.special)
|
|
(extension ["[%" "]"] @punctuation.special)
|
|
(item_extension ["[%%" "]"] @punctuation.special)
|
|
(quoted_extension ["{%" "}"] @punctuation.special)
|
|
(quoted_item_extension ["{%%" "}"] @punctuation.special)
|
|
|
|
"%" @punctuation.special
|
|
|
|
["(" ")" "[" "]" "{" "}" "[|" "|]" "[<" "[>"] @punctuation.bracket
|
|
|
|
(object_type ["<" ">"] @punctuation.bracket)
|
|
|
|
[
|
|
"," "." ";" ":" "=" "|" "~" "?" "+" "-" "!" ">" "&"
|
|
"->" ";;" ":>" "+=" ":=" ".."
|
|
] @punctuation.delimiter
|
|
|
|
; Operators
|
|
;----------
|
|
|
|
[
|
|
(prefix_operator)
|
|
(sign_operator)
|
|
(pow_operator)
|
|
(mult_operator)
|
|
(add_operator)
|
|
(concat_operator)
|
|
(rel_operator)
|
|
(and_operator)
|
|
(or_operator)
|
|
(assign_operator)
|
|
(hash_operator)
|
|
(indexing_operator)
|
|
(let_operator)
|
|
(and_operator)
|
|
(match_operator)
|
|
] @operator
|
|
|
|
(match_expression (match_operator) @keyword)
|
|
|
|
(value_definition [(let_operator) (let_and_operator)] @keyword)
|
|
|
|
["*" "#" "::" "<-"] @operator
|
|
|
|
; Attributes
|
|
;-----------
|
|
|
|
(attribute_id) @property
|
|
|
|
; Comments
|
|
;---------
|
|
|
|
[(comment) (line_number_directive) (directive) (shebang)] @comment @spell
|