mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-08 06:20:01 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
185 lines
2.2 KiB
Scheme
185 lines
2.2 KiB
Scheme
(variable_identifier) @variable
|
|
(constant_identifier) @constant
|
|
|
|
[
|
|
"assert"
|
|
"assert_eq"
|
|
"assert_neq"
|
|
"block"
|
|
"console"
|
|
"const"
|
|
"let"
|
|
"mapping"
|
|
"program"
|
|
"record"
|
|
"self"
|
|
"struct"
|
|
"then"
|
|
] @keyword
|
|
|
|
"in" @keyword.operator
|
|
|
|
[
|
|
"constant"
|
|
"private"
|
|
"public"
|
|
] @type.qualifier
|
|
|
|
"self" @variable.builtin
|
|
|
|
[
|
|
"finalize"
|
|
"function"
|
|
"inline"
|
|
"transition"
|
|
] @keyword.function
|
|
|
|
"import" @keyword.import
|
|
|
|
"return" @keyword.return
|
|
|
|
(return_arrow) @punctuation.delimiter
|
|
|
|
"for" @keyword.repeat
|
|
|
|
[
|
|
"else"
|
|
"if"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
(ternary_if)
|
|
(ternary_else)
|
|
] @keyword.conditional.ternary
|
|
|
|
[ "(" ")" "{" "}" "[" "]" ] @punctuation.bracket
|
|
|
|
[ ";" "," "::"] @punctuation.delimiter
|
|
|
|
[
|
|
"!"
|
|
|
|
"&&"
|
|
"||"
|
|
|
|
"=="
|
|
"!="
|
|
|
|
"<"
|
|
"<="
|
|
">"
|
|
">="
|
|
|
|
"&"
|
|
"|"
|
|
"^"
|
|
|
|
"<<"
|
|
">>"
|
|
|
|
"+"
|
|
"-"
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"**"
|
|
|
|
"="
|
|
|
|
"+="
|
|
"-="
|
|
"*="
|
|
"/="
|
|
"%="
|
|
"**="
|
|
|
|
"<<="
|
|
">>="
|
|
|
|
"&="
|
|
"|="
|
|
"^="
|
|
|
|
"&&="
|
|
"||="
|
|
|
|
] @operator
|
|
|
|
(comment) @comment @spell
|
|
|
|
(boolean_literal) @boolean
|
|
|
|
(constant_declaration
|
|
(identifier) @constant)
|
|
|
|
[
|
|
(program_id)
|
|
(this_program_id)
|
|
] @string.special
|
|
|
|
;record declaration
|
|
(record_declaration (identifier) @variable.member)
|
|
|
|
;struct component
|
|
(struct_component_declaration
|
|
(identifier) @variable.member)
|
|
|
|
(type) @type
|
|
|
|
(associated_constant) @constant
|
|
|
|
[
|
|
(block_height)
|
|
(self_caller)
|
|
(self_signer)
|
|
] @constant.builtin
|
|
|
|
(free_function_call
|
|
(locator
|
|
(identifier) @function))
|
|
|
|
(record_type
|
|
(locator
|
|
(identifier) @variable.member))
|
|
|
|
(transition_declaration
|
|
name: (identifier) @function.builtin)
|
|
|
|
(finalizer
|
|
name: (identifier) @function.builtin)
|
|
|
|
(free_function_call
|
|
(identifier) @function.call)
|
|
|
|
(function_declaration
|
|
name: (identifier) @function)
|
|
|
|
(inline_declaration
|
|
name: (identifier) @function.macro)
|
|
|
|
(method_call
|
|
. (_)
|
|
. (identifier) @function.method.call)
|
|
|
|
(function_parameter
|
|
(identifier) @variable.parameter)
|
|
|
|
(struct_declaration
|
|
name: (identifier) @variable.member)
|
|
|
|
(variable_declaration
|
|
(identifier_or_identifiers
|
|
(identifier) @variable))
|
|
|
|
[
|
|
(address_literal)
|
|
(signature_literal)
|
|
((affine_group_literal) (#set! "priority" 101))
|
|
(field_literal)
|
|
(product_group_literal)
|
|
(scalar_literal)
|
|
(signed_literal)
|
|
(unsigned_literal)
|
|
] @number
|
|
|
|
(annotation) @attribute
|