mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 14:00:00 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
251 lines
3.8 KiB
Scheme
251 lines
3.8 KiB
Scheme
;; Forked from tree-sitter-go
|
|
;; Copyright (c) 2014 Max Brunsfeld (The MIT License)
|
|
|
|
;;
|
|
; Identifiers
|
|
|
|
(type_identifier) @type
|
|
(type_spec name: (type_identifier) @type.definition)
|
|
(field_identifier) @property
|
|
(identifier) @variable
|
|
(package_identifier) @module
|
|
|
|
(parameter_declaration (identifier) @variable.parameter)
|
|
(variadic_parameter_declaration (identifier) @variable.parameter)
|
|
|
|
(label_name) @label
|
|
|
|
(const_spec
|
|
name: (identifier) @constant)
|
|
|
|
; Function calls
|
|
|
|
(call_expression
|
|
function: (identifier) @function.call)
|
|
|
|
(call_expression
|
|
function: (selector_expression
|
|
field: (field_identifier) @function.method.call))
|
|
|
|
; Function definitions
|
|
|
|
(function_declaration
|
|
name: (identifier) @function)
|
|
|
|
(method_declaration
|
|
name: (field_identifier) @function.method)
|
|
|
|
(method_spec
|
|
name: (field_identifier) @function.method)
|
|
|
|
; Constructors
|
|
|
|
((call_expression (identifier) @constructor)
|
|
(#lua-match? @constructor "^[nN]ew.+$"))
|
|
|
|
((call_expression (identifier) @constructor)
|
|
(#lua-match? @constructor "^[mM]ake.+$"))
|
|
|
|
; Operators
|
|
|
|
[
|
|
"--"
|
|
"-"
|
|
"-="
|
|
":="
|
|
"!"
|
|
"!="
|
|
"..."
|
|
"*"
|
|
"*"
|
|
"*="
|
|
"/"
|
|
"/="
|
|
"&"
|
|
"&&"
|
|
"&="
|
|
"&^"
|
|
"&^="
|
|
"%"
|
|
"%="
|
|
"^"
|
|
"^="
|
|
"+"
|
|
"++"
|
|
"+="
|
|
"<-"
|
|
"<"
|
|
"<<"
|
|
"<<="
|
|
"<="
|
|
"="
|
|
"=="
|
|
">"
|
|
">="
|
|
">>"
|
|
">>="
|
|
"|"
|
|
"|="
|
|
"||"
|
|
"~"
|
|
] @operator
|
|
|
|
; Keywords
|
|
|
|
[
|
|
"break"
|
|
"const"
|
|
"continue"
|
|
"default"
|
|
"defer"
|
|
"goto"
|
|
"interface"
|
|
"range"
|
|
"select"
|
|
"struct"
|
|
"type"
|
|
"var"
|
|
"fallthrough"
|
|
] @keyword
|
|
|
|
"func" @keyword.function
|
|
"return" @keyword.return
|
|
"go" @keyword.coroutine
|
|
|
|
"for" @keyword.repeat
|
|
|
|
[
|
|
"import"
|
|
"package"
|
|
] @keyword.import
|
|
|
|
[
|
|
"else"
|
|
"case"
|
|
"switch"
|
|
"if"
|
|
] @keyword.conditional
|
|
|
|
|
|
;; Builtin types
|
|
|
|
[ "chan" "map" ] @type.builtin
|
|
|
|
((type_identifier) @type.builtin
|
|
(#any-of? @type.builtin
|
|
"any"
|
|
"bool"
|
|
"byte"
|
|
"comparable"
|
|
"complex128"
|
|
"complex64"
|
|
"error"
|
|
"float32"
|
|
"float64"
|
|
"int"
|
|
"int16"
|
|
"int32"
|
|
"int64"
|
|
"int8"
|
|
"rune"
|
|
"string"
|
|
"uint"
|
|
"uint16"
|
|
"uint32"
|
|
"uint64"
|
|
"uint8"
|
|
"uintptr"))
|
|
|
|
|
|
;; Builtin functions
|
|
|
|
((identifier) @function.builtin
|
|
(#any-of? @function.builtin
|
|
"append"
|
|
"cap"
|
|
"clear"
|
|
"close"
|
|
"complex"
|
|
"copy"
|
|
"delete"
|
|
"imag"
|
|
"len"
|
|
"make"
|
|
"max"
|
|
"min"
|
|
"new"
|
|
"panic"
|
|
"print"
|
|
"println"
|
|
"real"
|
|
"recover"))
|
|
|
|
|
|
; Delimiters
|
|
|
|
"." @punctuation.delimiter
|
|
"," @punctuation.delimiter
|
|
":" @punctuation.delimiter
|
|
";" @punctuation.delimiter
|
|
|
|
"(" @punctuation.bracket
|
|
")" @punctuation.bracket
|
|
"{" @punctuation.bracket
|
|
"}" @punctuation.bracket
|
|
"[" @punctuation.bracket
|
|
"]" @punctuation.bracket
|
|
|
|
|
|
; Literals
|
|
|
|
(interpreted_string_literal) @string
|
|
(raw_string_literal) @string
|
|
(rune_literal) @string
|
|
(escape_sequence) @string.escape
|
|
|
|
(int_literal) @number
|
|
(float_literal) @number.float
|
|
(imaginary_literal) @number
|
|
|
|
[
|
|
(true)
|
|
(false)
|
|
] @boolean
|
|
|
|
[
|
|
(nil)
|
|
(iota)
|
|
] @constant.builtin
|
|
|
|
(keyed_element
|
|
. (literal_element (identifier) @variable.member))
|
|
(field_declaration name: (field_identifier) @variable.member)
|
|
|
|
; Comments
|
|
|
|
(comment) @comment @spell
|
|
|
|
;; Doc Comments
|
|
|
|
(source_file . (comment)+ @comment.documentation)
|
|
|
|
(source_file
|
|
(comment)+ @comment.documentation
|
|
. (const_declaration))
|
|
|
|
(source_file
|
|
(comment)+ @comment.documentation
|
|
. (function_declaration))
|
|
|
|
(source_file
|
|
(comment)+ @comment.documentation
|
|
. (type_declaration))
|
|
|
|
(source_file
|
|
(comment)+ @comment.documentation
|
|
. (var_declaration))
|
|
|
|
; Spell
|
|
|
|
((interpreted_string_literal) @spell
|
|
(#not-has-parent? @spell import_spec))
|