mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 14:00:00 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
120 lines
1.7 KiB
Scheme
120 lines
1.7 KiB
Scheme
(comment) @comment @spell
|
|
(afx_comment) @comment @spell
|
|
|
|
; identifiers afx
|
|
(afx_opening_element
|
|
(afx_identifier) @tag)
|
|
(afx_closing_element
|
|
(afx_identifier) @tag)
|
|
(afx_element_self_closing
|
|
(afx_identifier) @tag)
|
|
|
|
(afx_attribute
|
|
(afx_property_identifier) @tag.attribute)
|
|
|
|
(afx_text) @spell
|
|
|
|
; identifiers eel
|
|
|
|
(eel_object_path
|
|
(eel_path_identifier) @variable.builtin
|
|
(#any-of? @variable.builtin "this" "props")
|
|
)
|
|
|
|
(eel_object_path
|
|
(eel_path_identifier) @variable)
|
|
|
|
(eel_object_pair
|
|
key: (eel_property_name) @property)
|
|
|
|
(eel_method_name) @function
|
|
|
|
(eel_parameter) @variable
|
|
|
|
; identifiers fusion
|
|
; -----------
|
|
|
|
(path_part) @property
|
|
(meta_property) @attribute
|
|
(prototype_signature
|
|
"prototype" @keyword
|
|
|
|
)
|
|
(include_statement
|
|
[
|
|
"include"
|
|
] @keyword.import
|
|
(source_file) @string.special.url
|
|
)
|
|
|
|
(namespace_declaration
|
|
"namespace" @keyword
|
|
(alias_namespace) @module)
|
|
|
|
(type
|
|
name: (type_name) @type)
|
|
|
|
; tokens
|
|
; ------
|
|
(afx_opening_element
|
|
[
|
|
"<"
|
|
">"
|
|
] @punctuation.bracket)
|
|
|
|
(afx_closing_element
|
|
[
|
|
"<"
|
|
">"
|
|
"/"
|
|
] @punctuation.bracket)
|
|
|
|
(afx_element_self_closing
|
|
[
|
|
"<"
|
|
"/>"
|
|
] @punctuation.bracket)
|
|
|
|
[
|
|
(package_name)
|
|
(alias_namespace)
|
|
] @module
|
|
|
|
(namespace_declaration "=" @operator)
|
|
(assignment "=" @operator)
|
|
(copy "<" @operator)
|
|
(deletion) @operator
|
|
(eel_binary_expression
|
|
operator: _ @operator)
|
|
(eel_not_expression
|
|
[
|
|
"!"
|
|
"not"
|
|
] @operator)
|
|
|
|
(string) @string
|
|
(number) @number
|
|
(boolean) @boolean
|
|
(null) @constant.builtin
|
|
|
|
(value_expression
|
|
start: _ @punctuation.special
|
|
end: _ @punctuation.special
|
|
)
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
":"
|
|
"."
|
|
"?"
|
|
] @punctuation.delimiter
|
|
|
|
(eel_ternary_expression
|
|
["?" ":"] @keyword.conditional.ternary)
|