mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-09 15:00:04 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
70 lines
1.7 KiB
Scheme
70 lines
1.7 KiB
Scheme
(comment) @comment @spell
|
|
|
|
["if" "elif"] @keyword.conditional
|
|
(if (else "else" @keyword.conditional))
|
|
|
|
["while" "for"] @keyword.repeat
|
|
(while (else "else" @keyword.repeat))
|
|
(for (else "else" @keyword.repeat))
|
|
|
|
["try" "catch" "finally"] @keyword.exception
|
|
(try (else "else" @keyword.exception))
|
|
|
|
"use" @keyword.import
|
|
(import (bareword) @string.special.path)
|
|
|
|
(wildcard ["*" "**" "?"] @character.special)
|
|
|
|
(command argument: (bareword) @variable.parameter)
|
|
(command head: (identifier) @function.call)
|
|
((command head: (identifier) @keyword.return)
|
|
(#eq? @keyword.return "return"))
|
|
((command (identifier) @keyword.operator)
|
|
(#any-of? @keyword.operator "and" "or" "coalesce"))
|
|
[
|
|
"+" "-" "*" "/" "%" "<" "<=""==" "!=" ">"
|
|
">=" "<s" "<=s" "==s" "!=s" ">s" ">=s"
|
|
] @function.builtin
|
|
|
|
[">" "<" ">>" "<>" "|"] @operator
|
|
|
|
(io_port) @number
|
|
|
|
(function_definition
|
|
"fn" @keyword.function
|
|
(identifier) @function)
|
|
|
|
(parameter_list) @variable.parameter
|
|
(parameter_list "|" @punctuation.bracket)
|
|
|
|
["var" "set" "tmp" "del"] @keyword
|
|
(variable_declaration
|
|
(lhs (identifier) @variable))
|
|
|
|
(variable_assignment
|
|
(lhs (identifier) @variable))
|
|
|
|
(temporary_assignment
|
|
(lhs (identifier) @variable))
|
|
|
|
(variable_deletion
|
|
(identifier) @variable)
|
|
|
|
|
|
(number) @number
|
|
(string) @string
|
|
|
|
(variable (identifier) @variable)
|
|
((variable (identifier) @function)
|
|
(#match? @function ".+\\~$"))
|
|
((variable (identifier) @boolean)
|
|
(#any-of? @boolean "true" "false"))
|
|
((variable (identifier) @constant.builtin)
|
|
(#any-of? @constant.builtin
|
|
"_" "after-chdir" "args" "before-chdir" "buildinfo" "nil"
|
|
"notify-bg-job-success" "num-bg-jobs" "ok" "paths" "pid"
|
|
"pwd" "value-out-indicator" "version"))
|
|
|
|
["$" "@"] @punctuation.special
|
|
["(" ")" "[" "]" "{" "}"] @punctuation.bracket
|
|
";" @punctuation.delimiter
|