mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 14:00:00 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
171 lines
2.3 KiB
Scheme
171 lines
2.3 KiB
Scheme
;; Text
|
|
|
|
;; Imports
|
|
|
|
(missing_import) @keyword.import
|
|
|
|
(local_import) @string.special.path
|
|
|
|
(http_import) @string.special.url
|
|
|
|
[
|
|
(env_variable)
|
|
(import_hash)
|
|
] @string.special
|
|
|
|
[ (import_as_location) (import_as_text) ] @type
|
|
|
|
;; Types
|
|
|
|
([
|
|
(let_binding (label) @type)
|
|
(union_type_entry (label) @type)
|
|
] (#lua-match? @type "^%u"))
|
|
|
|
((primitive_expression
|
|
(identifier (label) @type)
|
|
(selector (label) @type)) @variable
|
|
(#lua-match? @variable "^[A-Z][^.]*$"))
|
|
|
|
;; Parameters
|
|
|
|
(lambda_expression label: (label) @variable.parameter)
|
|
|
|
;; Variables
|
|
|
|
(label) @variable
|
|
|
|
(identifier [
|
|
(label) @variable
|
|
(de_bruijn_index) @operator
|
|
])
|
|
|
|
(let_binding label: (label) @variable)
|
|
|
|
; Fields
|
|
|
|
(record_literal_entry (label) @variable.member)
|
|
|
|
(record_type_entry (label) @variable.member)
|
|
|
|
(selector
|
|
(selector_dot)
|
|
(_) @variable.member)
|
|
|
|
;; Keywords
|
|
|
|
(env_import) @keyword
|
|
|
|
[
|
|
"let"
|
|
"in"
|
|
"assert"
|
|
] @keyword
|
|
|
|
[
|
|
"using"
|
|
"as"
|
|
"with"
|
|
] @keyword.operator
|
|
|
|
;; Operators
|
|
|
|
[
|
|
(type_operator)
|
|
(assign_operator)
|
|
(lambda_operator)
|
|
(arrow_operator)
|
|
(infix_operator)
|
|
(completion_operator)
|
|
(assert_operator)
|
|
(forall_operator)
|
|
(empty_record_literal)
|
|
] @operator
|
|
|
|
;; Builtins
|
|
|
|
(builtin_function) @function.builtin
|
|
(builtin [
|
|
"Natural"
|
|
"Natural/build"
|
|
"Natural/fold"
|
|
"Natural/isZero"
|
|
"Natural/even"
|
|
"Natural/odd"
|
|
"Natural/subtract"
|
|
"Natural/toInteger"
|
|
"Natural/show"
|
|
"Integer"
|
|
"Integer/toDouble"
|
|
"Integer/show"
|
|
"Integer/negate"
|
|
"Integer/clamp"
|
|
"Double"
|
|
"Double/show"
|
|
"List"
|
|
"List/build"
|
|
"List/fold"
|
|
"List/length"
|
|
"List/head"
|
|
"List/last"
|
|
"List/indexed"
|
|
"List/reverse"
|
|
"Text"
|
|
"Text/show"
|
|
"Text/replace"
|
|
"Optional"
|
|
"Date"
|
|
"Time"
|
|
"TimeZone"
|
|
"Type"
|
|
"Kind"
|
|
"Sort"
|
|
] @type.builtin)
|
|
|
|
;; Punctuation
|
|
|
|
[ "," "|" ] @punctuation.delimiter
|
|
(selector_dot) @punctuation.delimiter
|
|
|
|
[ "{" "}" ] @punctuation.bracket
|
|
|
|
[ "[" "]" ] @punctuation.bracket
|
|
|
|
[ "(" ")" ] @punctuation.bracket
|
|
|
|
[ "<" ">" ] @punctuation.bracket
|
|
|
|
;; Conditionals
|
|
|
|
[
|
|
"if"
|
|
"then"
|
|
"else"
|
|
] @keyword.conditional
|
|
|
|
;; Literals
|
|
|
|
(text_literal) @string
|
|
(interpolation "}" @string)
|
|
[
|
|
(double_quote_escaped)
|
|
(single_quote_escaped)
|
|
] @string.escape
|
|
|
|
[
|
|
(integer_literal)
|
|
(natural_literal)
|
|
] @number
|
|
|
|
(double_literal) @number.float
|
|
|
|
(boolean_literal) @boolean
|
|
|
|
(builtin "None") @constant.builtin
|
|
|
|
;; Comments
|
|
|
|
[
|
|
(line_comment)
|
|
(block_comment)
|
|
] @comment @spell
|