mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-03 12:06:55 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
186 lines
3.3 KiB
Scheme
186 lines
3.3 KiB
Scheme
[
|
|
"(" ")"
|
|
"{" "}"
|
|
"[" "]"
|
|
"[[" "]]"
|
|
"((" "))"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
";"
|
|
";;"
|
|
";&"
|
|
";;&"
|
|
"&"
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
">"
|
|
">>"
|
|
"<"
|
|
"<<"
|
|
"&&"
|
|
"|"
|
|
"|&"
|
|
"||"
|
|
"="
|
|
"+="
|
|
"=~"
|
|
"=="
|
|
"!="
|
|
|
|
"&>"
|
|
"&>>"
|
|
"<&"
|
|
">&"
|
|
">|"
|
|
"<&-"
|
|
">&-"
|
|
|
|
"<<-"
|
|
"<<<"
|
|
|
|
".."
|
|
] @operator
|
|
|
|
; Do *not* spell check strings since they typically have some sort of
|
|
; interpolation in them, or, are typically used for things like filenames, URLs,
|
|
; flags and file content.
|
|
[
|
|
(string)
|
|
(raw_string)
|
|
(ansi_c_string)
|
|
(heredoc_body)
|
|
] @string
|
|
|
|
[
|
|
(heredoc_start)
|
|
(heredoc_end)
|
|
] @label
|
|
|
|
(variable_assignment (word) @string)
|
|
(command argument: "$" @string) ; bare dollar
|
|
|
|
[
|
|
"if"
|
|
"then"
|
|
"else"
|
|
"elif"
|
|
"fi"
|
|
"case"
|
|
"in"
|
|
"esac"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
"for"
|
|
"do"
|
|
"done"
|
|
"select"
|
|
"until"
|
|
"while"
|
|
] @keyword.repeat
|
|
|
|
[
|
|
"declare"
|
|
"typeset"
|
|
"export"
|
|
"readonly"
|
|
"local"
|
|
"unset"
|
|
"unsetenv"
|
|
] @keyword
|
|
|
|
"function" @keyword.function
|
|
|
|
(special_variable_name) @constant
|
|
|
|
; trap -l
|
|
((word) @constant.builtin
|
|
(#match? @constant.builtin "^SIG(HUP|INT|QUIT|ILL|TRAP|ABRT|BUS|FPE|KILL|USR[12]|SEGV|PIPE|ALRM|TERM|STKFLT|CHLD|CONT|STOP|TSTP|TT(IN|OU)|URG|XCPU|XFSZ|VTALRM|PROF|WINCH|IO|PWR|SYS|RTMIN([+]([1-9]|1[0-5]))?|RTMAX(-([1-9]|1[0-4]))?)$"))
|
|
|
|
((word) @boolean
|
|
(#any-of? @boolean "true" "false"))
|
|
|
|
(comment) @comment @spell
|
|
|
|
(test_operator) @operator
|
|
|
|
(command_substitution "$(" @punctuation.bracket)
|
|
(process_substitution "<(" @punctuation.bracket)
|
|
|
|
(arithmetic_expansion
|
|
[ "$((" "((" ] @punctuation.special
|
|
"))" @punctuation.special)
|
|
|
|
(arithmetic_expansion "," @punctuation.delimiter)
|
|
|
|
(ternary_expression [ "?" ":" ] @keyword.conditional.ternary)
|
|
|
|
(binary_expression operator: _ @operator)
|
|
(unary_expression operator: _ @operator)
|
|
(postfix_expression operator: _ @operator)
|
|
|
|
(function_definition
|
|
name: (word) @function)
|
|
|
|
(command_name (word) @function.call)
|
|
|
|
((command_name (word) @function.builtin)
|
|
(#any-of? @function.builtin
|
|
"alias" "bg" "bind" "break" "builtin" "caller" "cd"
|
|
"command" "compgen" "complete" "compopt" "continue"
|
|
"coproc" "dirs" "disown" "echo" "enable" "eval"
|
|
"exec" "exit" "fc" "fg" "getopts" "hash" "help"
|
|
"history" "jobs" "kill" "let" "logout" "mapfile"
|
|
"popd" "printf" "pushd" "pwd" "read" "readarray"
|
|
"return" "set" "shift" "shopt" "source" "suspend"
|
|
"test" "time" "times" "trap" "type" "typeset"
|
|
"ulimit" "umask" "unalias" "wait"))
|
|
|
|
(command
|
|
argument: [
|
|
(word) @variable.parameter
|
|
(concatenation (word) @variable.parameter)
|
|
])
|
|
|
|
(number) @number
|
|
((word) @number
|
|
(#lua-match? @number "^[0-9]+$"))
|
|
|
|
(file_redirect
|
|
destination: (word) @variable.parameter)
|
|
|
|
(file_descriptor) @operator
|
|
|
|
(simple_expansion
|
|
"$" @punctuation.special) @none
|
|
(expansion
|
|
"${" @punctuation.special
|
|
"}" @punctuation.special) @none
|
|
|
|
(expansion operator: _ @punctuation.special)
|
|
(expansion "@" . operator: _ @character.special)
|
|
|
|
((expansion
|
|
(subscript
|
|
index: (word) @character.special))
|
|
(#any-of? @character.special "@" "*"))
|
|
|
|
"``" @punctuation.special
|
|
|
|
(variable_name) @variable
|
|
|
|
((variable_name) @constant
|
|
(#lua-match? @constant "^[A-Z][A-Z_0-9]*$"))
|
|
|
|
(case_item
|
|
value: (word) @variable.parameter)
|
|
|
|
[
|
|
(regex)
|
|
(extglob_pattern)
|
|
] @string.regexp
|
|
|
|
((program . (comment) @keyword.directive)
|
|
(#lua-match? @keyword.directive "^#!/"))
|