mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-06 21:40:03 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
190 lines
4.3 KiB
Scheme
190 lines
4.3 KiB
Scheme
;; highlight queries.
|
|
;; See the syntax at https://tree-sitter.github.io/tree-sitter/using-parsers#pattern-matching-with-queries
|
|
;; See also https://github.com/nvim-treesitter/nvim-treesitter/blob/master/CONTRIBUTING.md#parser-configurations
|
|
;; for a list of recommended @ tags, though not all of them have matching
|
|
;; highlights in neovim.
|
|
|
|
[
|
|
"abort"
|
|
"abs"
|
|
"abstract"
|
|
"accept"
|
|
"access"
|
|
"all"
|
|
"array"
|
|
"at"
|
|
"begin"
|
|
"declare"
|
|
"delay"
|
|
"delta"
|
|
"digits"
|
|
"do"
|
|
"end"
|
|
"entry"
|
|
"exit"
|
|
"generic"
|
|
"interface"
|
|
"is"
|
|
"limited"
|
|
"null"
|
|
"of"
|
|
"others"
|
|
"out"
|
|
"pragma"
|
|
"private"
|
|
"range"
|
|
"synchronized"
|
|
"tagged"
|
|
"task"
|
|
"terminate"
|
|
"until"
|
|
"when"
|
|
] @keyword
|
|
[
|
|
"aliased"
|
|
"constant"
|
|
"renames"
|
|
] @keyword.storage
|
|
[
|
|
"mod"
|
|
"new"
|
|
"protected"
|
|
"record"
|
|
"subtype"
|
|
"type"
|
|
] @keyword.type
|
|
[
|
|
"with"
|
|
"use"
|
|
] @keyword.import
|
|
[
|
|
"body"
|
|
"function"
|
|
"overriding"
|
|
"procedure"
|
|
"package"
|
|
"separate"
|
|
] @keyword.function
|
|
[
|
|
"and"
|
|
"in"
|
|
"not"
|
|
"or"
|
|
"xor"
|
|
] @keyword.operator
|
|
[
|
|
"while"
|
|
"loop"
|
|
"for"
|
|
"parallel"
|
|
"reverse"
|
|
"some"
|
|
] @keyword.repeat
|
|
[
|
|
"return"
|
|
] @keyword.return
|
|
[
|
|
"case"
|
|
"if"
|
|
"else"
|
|
"then"
|
|
"elsif"
|
|
"select"
|
|
] @keyword.conditional
|
|
[
|
|
"exception"
|
|
"raise"
|
|
] @keyword.exception
|
|
(comment) @comment @spell
|
|
(string_literal) @string
|
|
(character_literal) @string
|
|
(numeric_literal) @number
|
|
|
|
;; Highlight the name of subprograms
|
|
(procedure_specification name: (_) @function)
|
|
(function_specification name: (_) @function)
|
|
(package_declaration name: (_) @function)
|
|
(package_body name: (_) @function)
|
|
(generic_instantiation name: (_) @function)
|
|
(entry_declaration . (identifier) @function)
|
|
|
|
;; Some keywords should take different categories depending on the context
|
|
(use_clause "use" @keyword.import "type" @keyword.import)
|
|
(with_clause "private" @keyword.import)
|
|
(with_clause "limited" @keyword.import)
|
|
(use_clause (_) @module)
|
|
(with_clause (_) @module)
|
|
|
|
(loop_statement "end" @keyword.repeat)
|
|
(if_statement "end" @keyword.conditional)
|
|
(loop_parameter_specification "in" @keyword.repeat)
|
|
(loop_parameter_specification "in" @keyword.repeat)
|
|
(iterator_specification ["in" "of"] @keyword.repeat)
|
|
(range_attribute_designator "range" @keyword.repeat)
|
|
|
|
(raise_statement "with" @keyword.exception)
|
|
|
|
(gnatprep_declarative_if_statement) @keyword.directive
|
|
(gnatprep_if_statement) @keyword.directive
|
|
(gnatprep_identifier) @keyword.directive
|
|
|
|
(subprogram_declaration "is" @keyword.function "abstract" @keyword.function)
|
|
(aspect_specification "with" @keyword.function)
|
|
|
|
(full_type_declaration "is" @keyword.type)
|
|
(subtype_declaration "is" @keyword.type)
|
|
(record_definition "end" @keyword.type)
|
|
(full_type_declaration (_ "access" @keyword.type))
|
|
(array_type_definition "array" @keyword.type "of" @keyword.type)
|
|
(access_to_object_definition "access" @keyword.type)
|
|
(access_to_object_definition "access" @keyword.type
|
|
[
|
|
(general_access_modifier "constant" @keyword.type)
|
|
(general_access_modifier "all" @keyword.type)
|
|
]
|
|
)
|
|
(range_constraint "range" @keyword.type)
|
|
(signed_integer_type_definition "range" @keyword.type)
|
|
(index_subtype_definition "range" @keyword.type)
|
|
(record_type_definition "abstract" @keyword.type)
|
|
(record_type_definition "tagged" @keyword.type)
|
|
(record_type_definition "limited" @keyword.type)
|
|
(record_type_definition (record_definition "null" @keyword.type))
|
|
(private_type_declaration "is" @keyword.type "private" @keyword.type)
|
|
(private_type_declaration "tagged" @keyword.type)
|
|
(private_type_declaration "limited" @keyword.type)
|
|
(task_type_declaration "task" @keyword.type "is" @keyword.type)
|
|
|
|
;; Gray the body of expression functions
|
|
(expression_function_declaration
|
|
(function_specification)
|
|
"is"
|
|
(_) @attribute
|
|
)
|
|
(subprogram_declaration (aspect_specification) @attribute)
|
|
|
|
;; Highlight full subprogram specifications
|
|
;(subprogram_body
|
|
; [
|
|
; (procedure_specification)
|
|
; (function_specification)
|
|
; ] @function.spec
|
|
;)
|
|
|
|
((comment) @comment.documentation
|
|
. [
|
|
(entry_declaration)
|
|
(subprogram_declaration)
|
|
(parameter_specification)
|
|
])
|
|
|
|
(compilation_unit
|
|
. (comment) @comment.documentation)
|
|
|
|
(component_list
|
|
(component_declaration)
|
|
. (comment) @comment.documentation)
|
|
|
|
(enumeration_type_definition
|
|
(identifier)
|
|
. (comment) @comment.documentation)
|