mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 05:50:04 -04:00
6b5b37cc3e
* feat(fusion): update tests * fix(fusion): update lockfile * fix(fusion): update to (highlight breaking) version 1.1.0 * update grammer to introduce afx support * update tests and queries * fix: revert lockfile update of unrelated grammars * fix: update to 1.1.1 and fix hightlights * fix: use @tag.attribute capture to match specs Co-authored-by: Jirgn <jirgn76@googlemail.com>
111 lines
1.5 KiB
Scheme
111 lines
1.5 KiB
Scheme
(comment) @comment
|
|
(afx_comment) @comment
|
|
|
|
; identifiers afx
|
|
(afx_opening_element
|
|
(afx_identifier) @tag)
|
|
(afx_closing_element
|
|
(afx_identifier) @tag)
|
|
(afx_element_self_closing
|
|
(afx_identifier) @tag)
|
|
|
|
(afx_attribute
|
|
(afx_property_identifier) @tag.attribute)
|
|
|
|
; identifiers eel
|
|
|
|
(eel_object_path
|
|
(eel_path_identifier) @variable.builtin
|
|
(#match? @variable.builtin "^(this|props)$")
|
|
)
|
|
|
|
(eel_object_path
|
|
(eel_path_identifier) @variable)
|
|
|
|
(eel_object_pair
|
|
key: (eel_property_name) @property)
|
|
|
|
(eel_method_name) @function
|
|
|
|
(eel_parameter) @variable
|
|
|
|
; identifiers fusion
|
|
; -----------
|
|
|
|
(path_part) @property
|
|
(meta_property) @attribute
|
|
(prototype_signature
|
|
"prototype" @keyword
|
|
|
|
)
|
|
(include_statement
|
|
[
|
|
"include"
|
|
] @include
|
|
(source_file) @text.uri
|
|
)
|
|
|
|
(namespace_declaration
|
|
"namespace" @keyword
|
|
(alias_namespace) @namespace)
|
|
|
|
(type
|
|
name: (type_name) @type)
|
|
|
|
; tokens
|
|
; ------
|
|
(afx_opening_element
|
|
[
|
|
"<"
|
|
">"
|
|
] @punctuation.bracket)
|
|
|
|
(afx_closing_element
|
|
[
|
|
"<"
|
|
">"
|
|
"/"
|
|
] @punctuation.bracket)
|
|
|
|
(afx_element_self_closing
|
|
[
|
|
"<"
|
|
"/>"
|
|
] @punctuation.bracket)
|
|
|
|
[
|
|
(package_name)
|
|
(alias_namespace)
|
|
] @namespace
|
|
|
|
(namespace_declaration "=" @operator)
|
|
(assignment "=" @operator)
|
|
(copy "<" @operator)
|
|
(deletion) @operator
|
|
(eel_binary_expression
|
|
operator: _ @operator)
|
|
(eel_not_expression
|
|
[
|
|
"!"
|
|
"not"
|
|
] @operator)
|
|
|
|
(string) @string
|
|
(number) @number
|
|
(boolean) @boolean
|
|
(null) @constant.builtin
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
":"
|
|
"."
|
|
"?"
|
|
] @punctuation.delimiter
|