mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-07 22:10:01 -04:00
d198a75e2c
* fix(format): newline between top-level field defs * fixup: newline between node and comment * fixup: optimize pattern
88 lines
2.3 KiB
Scheme
88 lines
2.3 KiB
Scheme
((comment) @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
; Github actions ("run") / Gitlab CI ("scripts")
|
|
(block_mapping_pair
|
|
key: (flow_node) @_run
|
|
(#any-of? @_run "run" "script" "before_script" "after_script")
|
|
value:
|
|
(flow_node
|
|
(plain_scalar
|
|
(string_scalar) @injection.content)
|
|
(#set! injection.language "bash")))
|
|
|
|
(block_mapping_pair
|
|
key: (flow_node) @_run
|
|
(#any-of? @_run "run" "script" "before_script" "after_script")
|
|
value:
|
|
(block_node
|
|
(block_scalar) @injection.content
|
|
(#set! injection.language "bash")
|
|
(#offset! @injection.content 0 1 0 0)))
|
|
|
|
(block_mapping_pair
|
|
key: (flow_node) @_run
|
|
(#any-of? @_run "run" "script" "before_script" "after_script")
|
|
value:
|
|
(block_node
|
|
(block_sequence
|
|
(block_sequence_item
|
|
(flow_node
|
|
(plain_scalar
|
|
(string_scalar) @injection.content))
|
|
(#set! injection.language "bash")))))
|
|
|
|
(block_mapping_pair
|
|
key: (flow_node) @_run
|
|
(#any-of? @_run "script" "before_script" "after_script")
|
|
value:
|
|
(block_node
|
|
(block_sequence
|
|
(block_sequence_item
|
|
(block_node
|
|
(block_scalar) @injection.content
|
|
(#set! injection.language "bash")
|
|
(#offset! @injection.content 0 1 0 0))))))
|
|
|
|
; Prometheus Alertmanager ("expr")
|
|
(block_mapping_pair
|
|
key: (flow_node) @_expr
|
|
(#eq? @_expr "expr")
|
|
value:
|
|
(flow_node
|
|
(plain_scalar
|
|
(string_scalar) @injection.content)
|
|
(#set! injection.language "promql")))
|
|
|
|
(block_mapping_pair
|
|
key: (flow_node) @_expr
|
|
(#eq? @_expr "expr")
|
|
value:
|
|
(block_node
|
|
(block_scalar) @injection.content
|
|
(#set! injection.language "promql")
|
|
(#offset! @injection.content 0 1 0 0)))
|
|
|
|
(block_mapping_pair
|
|
key: (flow_node) @_expr
|
|
(#eq? @_expr "expr")
|
|
value:
|
|
(block_node
|
|
(block_sequence
|
|
(block_sequence_item
|
|
(flow_node
|
|
(plain_scalar
|
|
(string_scalar) @injection.content))
|
|
(#set! injection.language "promql")))))
|
|
|
|
(block_mapping_pair
|
|
key: (flow_node) @_expr
|
|
(#eq? @_expr "expr")
|
|
value:
|
|
(block_node
|
|
(block_sequence
|
|
(block_sequence_item
|
|
(block_node
|
|
(block_scalar) @injection.content
|
|
(#set! injection.language "promql")
|
|
(#offset! @injection.content 0 1 0 0))))))
|