mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-02 03:26:52 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
301 lines
4.1 KiB
Scheme
301 lines
4.1 KiB
Scheme
; CREDITS @maxbrunsfeld (maxbrunsfeld@gmail.com)
|
|
|
|
; Variables
|
|
|
|
(identifier) @variable
|
|
|
|
; Methods
|
|
|
|
(method_declaration
|
|
name: (identifier) @function.method)
|
|
(method_invocation
|
|
name: (identifier) @function.method.call)
|
|
|
|
(super) @function.builtin
|
|
|
|
; Parameters
|
|
|
|
(formal_parameter
|
|
name: (identifier) @variable.parameter)
|
|
|
|
(catch_formal_parameter
|
|
name: (identifier) @variable.parameter)
|
|
|
|
(spread_parameter
|
|
(variable_declarator
|
|
name: (identifier) @variable.parameter)) ; int... foo
|
|
|
|
;; Lambda parameter
|
|
|
|
(inferred_parameters (identifier) @variable.parameter) ; (x,y) -> ...
|
|
|
|
(lambda_expression
|
|
parameters: (identifier) @variable.parameter) ; x -> ...
|
|
|
|
; Operators
|
|
|
|
[
|
|
"+"
|
|
":"
|
|
"++"
|
|
"-"
|
|
"--"
|
|
"&"
|
|
"&&"
|
|
"|"
|
|
"||"
|
|
"!"
|
|
"!="
|
|
"=="
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"<"
|
|
"<="
|
|
">"
|
|
">="
|
|
"="
|
|
"-="
|
|
"+="
|
|
"*="
|
|
"/="
|
|
"%="
|
|
"->"
|
|
"^"
|
|
"^="
|
|
"&="
|
|
"|="
|
|
"~"
|
|
">>"
|
|
">>>"
|
|
"<<"
|
|
"::"
|
|
] @operator
|
|
|
|
; Types
|
|
|
|
(interface_declaration
|
|
name: (identifier) @type)
|
|
(annotation_type_declaration
|
|
name: (identifier) @type)
|
|
(class_declaration
|
|
name: (identifier) @type)
|
|
(record_declaration
|
|
name: (identifier) @type)
|
|
(enum_declaration
|
|
name: (identifier) @type)
|
|
(constructor_declaration
|
|
name: (identifier) @type)
|
|
(type_identifier) @type
|
|
((type_identifier) @type.builtin
|
|
(#eq? @type.builtin "var"))
|
|
((method_invocation
|
|
object: (identifier) @type)
|
|
(#lua-match? @type "^[A-Z]"))
|
|
((method_reference
|
|
. (identifier) @type)
|
|
(#lua-match? @type "^[A-Z]"))
|
|
|
|
((field_access
|
|
object: (identifier) @type)
|
|
(#lua-match? @type "^[A-Z]"))
|
|
(scoped_identifier
|
|
(identifier) @type
|
|
(#lua-match? @type "^[A-Z]"))
|
|
|
|
; Fields
|
|
|
|
(field_declaration
|
|
declarator: (variable_declarator
|
|
name: (identifier) @variable.member))
|
|
|
|
(field_access
|
|
field: (identifier) @variable.member)
|
|
|
|
[
|
|
(boolean_type)
|
|
(integral_type)
|
|
(floating_point_type)
|
|
(void_type)
|
|
] @type.builtin
|
|
|
|
; Variables
|
|
|
|
((identifier) @constant
|
|
(#lua-match? @constant "^[A-Z_][A-Z%d_]+$"))
|
|
|
|
(this) @variable.builtin
|
|
|
|
; Annotations
|
|
|
|
(annotation
|
|
"@" @attribute
|
|
name: (identifier) @attribute)
|
|
(marker_annotation
|
|
"@" @attribute
|
|
name: (identifier) @attribute)
|
|
|
|
; Literals
|
|
|
|
(string_literal) @string
|
|
|
|
(escape_sequence) @string.escape
|
|
|
|
(character_literal) @character
|
|
|
|
[
|
|
(hex_integer_literal)
|
|
(decimal_integer_literal)
|
|
(octal_integer_literal)
|
|
(binary_integer_literal)
|
|
] @number
|
|
|
|
[
|
|
(decimal_floating_point_literal)
|
|
(hex_floating_point_literal)
|
|
] @number.float
|
|
|
|
[
|
|
(true)
|
|
(false)
|
|
] @boolean
|
|
|
|
(null_literal) @constant.builtin
|
|
|
|
; Keywords
|
|
|
|
[
|
|
"assert"
|
|
"class"
|
|
"record"
|
|
"default"
|
|
"enum"
|
|
"extends"
|
|
"implements"
|
|
"instanceof"
|
|
"interface"
|
|
"@interface"
|
|
"permits"
|
|
"to"
|
|
"with"
|
|
] @keyword
|
|
|
|
(synchronized_statement
|
|
"synchronized" @keyword)
|
|
|
|
[
|
|
"abstract"
|
|
"final"
|
|
"native"
|
|
"non-sealed"
|
|
"open"
|
|
"private"
|
|
"protected"
|
|
"public"
|
|
"sealed"
|
|
"static"
|
|
"strictfp"
|
|
"transitive"
|
|
] @type.qualifier
|
|
|
|
(modifiers
|
|
"synchronized" @type.qualifier)
|
|
|
|
[
|
|
"transient"
|
|
"volatile"
|
|
] @keyword.storage
|
|
|
|
[
|
|
"return"
|
|
"yield"
|
|
] @keyword.return
|
|
|
|
[
|
|
"new"
|
|
] @keyword.operator
|
|
|
|
; Conditionals
|
|
|
|
[
|
|
"if"
|
|
"else"
|
|
"switch"
|
|
"case"
|
|
] @keyword.conditional
|
|
|
|
(ternary_expression ["?" ":"] @keyword.conditional.ternary)
|
|
|
|
; Loops
|
|
|
|
[
|
|
"for"
|
|
"while"
|
|
"do"
|
|
"continue"
|
|
"break"
|
|
] @keyword.repeat
|
|
|
|
; Includes
|
|
|
|
[
|
|
"exports"
|
|
"import"
|
|
"module"
|
|
"opens"
|
|
"package"
|
|
"provides"
|
|
"requires"
|
|
"uses"
|
|
] @keyword.import
|
|
|
|
; Punctuation
|
|
|
|
[
|
|
";"
|
|
"."
|
|
"..."
|
|
","
|
|
] @punctuation.delimiter
|
|
|
|
[ "{" "}" ] @punctuation.bracket
|
|
|
|
[ "[" "]" ] @punctuation.bracket
|
|
|
|
[ "(" ")" ] @punctuation.bracket
|
|
|
|
(type_arguments [ "<" ">" ] @punctuation.bracket)
|
|
(type_parameters [ "<" ">" ] @punctuation.bracket)
|
|
|
|
(string_interpolation [ "\\{" "}" ] @punctuation.special)
|
|
|
|
; Exceptions
|
|
|
|
[
|
|
"throw"
|
|
"throws"
|
|
"finally"
|
|
"try"
|
|
"catch"
|
|
] @keyword.exception
|
|
|
|
; Labels
|
|
|
|
(labeled_statement
|
|
(identifier) @label)
|
|
|
|
; Comments
|
|
|
|
[
|
|
(line_comment)
|
|
(block_comment)
|
|
] @comment @spell
|
|
|
|
((block_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
|
|
|
|
((line_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///[^/]"))
|
|
|
|
((line_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///$"))
|