mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-03 12:06:55 -04:00
78b54eb7f6
Since 0.9, @lang syntax is still available as fallback but will soon be deprecated. Because of that, new syntax should be adopted once 0.9 becomes the baseline requirements for nvim-treesitter - update health check - update doc
46 lines
1.2 KiB
Scheme
46 lines
1.2 KiB
Scheme
(lua_statement
|
|
(script
|
|
(body) @injection.content
|
|
(#set! injection.language "lua")))
|
|
(lua_statement
|
|
(chunk) @injection.content
|
|
(#set! injection.language "lua"))
|
|
(ruby_statement
|
|
(script
|
|
(body) @injection.content
|
|
(#set! injection.language "ruby")))
|
|
(ruby_statement
|
|
(chunk) @injection.content
|
|
(#set! injection.language "ruby"))
|
|
(python_statement
|
|
(script
|
|
(body) @injection.content
|
|
(#set! injection.language "python")))
|
|
(python_statement
|
|
(chunk) @injection.content
|
|
(#set! injection.language "python"))
|
|
;; If we support perl at some point...
|
|
;; (perl_statement (script (body) @perl))
|
|
;; (perl_statement (chunk) @perl)
|
|
|
|
(autocmd_statement
|
|
(pattern) @injection.content
|
|
(#set! injection.language "regex"))
|
|
|
|
((set_item
|
|
option: (option_name) @_option
|
|
value: (set_value) @injection.content)
|
|
(#any-of? @_option
|
|
"includeexpr" "inex"
|
|
"printexpr" "pexpr"
|
|
"formatexpr" "fex"
|
|
"indentexpr" "inde"
|
|
"foldtext" "fdt"
|
|
"foldexpr" "fde"
|
|
"diffexpr" "dex"
|
|
"patchexpr" "pex"
|
|
"charconvert" "ccv")
|
|
(#set! injection.language "vim"))
|
|
|
|
((comment) @injection.content
|
|
(#set! injection.language "comment"))
|