mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-08 06:20:01 -04:00
bfb4601f48
These `include-children` were to alleviate an issue with empty range language tree, which has been fixed for Neovim nightly/Neovim 0.9.2
37 lines
925 B
Scheme
37 lines
925 B
Scheme
; inherits: html_tags
|
|
|
|
((style_element
|
|
(start_tag
|
|
(attribute
|
|
(attribute_name) @_attr
|
|
(quoted_attribute_value (attribute_value) @_lang)))
|
|
(raw_text) @injection.content)
|
|
(#eq? @_attr "lang")
|
|
(#any-of? @_lang "scss" "postcss" "less")
|
|
(#set! injection.language "scss"))
|
|
|
|
([
|
|
(raw_text_expr)
|
|
(raw_text_each)
|
|
] @injection.content
|
|
(#set! injection.language "javascript"))
|
|
|
|
((script_element
|
|
(start_tag
|
|
(attribute
|
|
(attribute_name) @_attr
|
|
(quoted_attribute_value (attribute_value) @_lang)))
|
|
(raw_text) @injection.content)
|
|
(#eq? @_attr "lang")
|
|
(#any-of? @_lang "ts" "typescript")
|
|
(#set! injection.language "typescript"))
|
|
|
|
((element
|
|
(start_tag
|
|
(attribute
|
|
(attribute_name) @_attr
|
|
(quoted_attribute_value
|
|
(attribute_value) @injection.language)))
|
|
(text) @injection.content)
|
|
(#eq? @_attr "lang")
|
|
(#eq? @injection.language "pug"))
|