mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-02 03:26:52 -04:00
cb8e810a1e
Since Java 23, java documentation supports markdown. It is supported by a '///' line comment followed by mandatory white space: https://openjdk.org/jeps/467
38 lines
1.1 KiB
Scheme
38 lines
1.1 KiB
Scheme
([
|
|
(block_comment)
|
|
(line_comment)
|
|
] @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
((block_comment) @injection.content
|
|
(#lua-match? @injection.content "/[*][!<*][^a-zA-Z]")
|
|
(#set! injection.language "doxygen"))
|
|
|
|
; markdown-style javadocs: https://openjdk.org/jeps/467
|
|
((line_comment) @injection.content
|
|
(#lua-match? @injection.content "^///%s")
|
|
(#offset! @injection.content 0 4 0 0)
|
|
(#set! injection.language "markdown_inline"))
|
|
|
|
; markdown-style javadocs: https://openjdk.org/jeps/467
|
|
((line_comment) @injection.content
|
|
(#lua-match? @injection.content "^///%s+[@]")
|
|
(#offset! @injection.content 0 4 0 0)
|
|
(#set! injection.language "doxygen"))
|
|
|
|
((method_invocation
|
|
name: (identifier) @_method
|
|
arguments: (argument_list
|
|
.
|
|
(string_literal
|
|
.
|
|
(_) @injection.content)))
|
|
(#any-of? @_method "format" "printf")
|
|
(#set! injection.language "printf"))
|
|
|
|
((method_invocation
|
|
object: (string_literal
|
|
(string_fragment) @injection.content)
|
|
name: (identifier) @_method)
|
|
(#eq? @_method "formatted")
|
|
(#set! injection.language "printf"))
|