mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-08 14:30:05 -04:00
78b54eb7f6
Since 0.9, @lang syntax is still available as fallback but will soon be deprecated. Because of that, new syntax should be adopted once 0.9 becomes the baseline requirements for nvim-treesitter - update health check - update doc
41 lines
1 KiB
Scheme
41 lines
1 KiB
Scheme
; inherits: html_tags
|
|
|
|
((style_element
|
|
(start_tag
|
|
(attribute
|
|
(attribute_name) @_attr
|
|
(quoted_attribute_value (attribute_value) @_lang)))
|
|
(raw_text) @injection.content)
|
|
(#eq? @_attr "lang")
|
|
(#any-of? @_lang "scss" "postcss" "less")
|
|
(#set! injection.language "scss")
|
|
(#set! injection.include-children))
|
|
|
|
([
|
|
(raw_text_expr)
|
|
(raw_text_each)
|
|
] @injection.content
|
|
(#set! injection.language "javascript")
|
|
(#set! injection.include-children))
|
|
|
|
((script_element
|
|
(start_tag
|
|
(attribute
|
|
(attribute_name) @_attr
|
|
(quoted_attribute_value (attribute_value) @_lang)))
|
|
(raw_text) @injection.content)
|
|
(#eq? @_attr "lang")
|
|
(#any-of? @_lang "ts" "typescript")
|
|
(#set! injection.language "typescript")
|
|
(#set! injection.include-children))
|
|
|
|
((element
|
|
(start_tag
|
|
(attribute
|
|
(attribute_name) @_attr
|
|
(quoted_attribute_value
|
|
(attribute_value) @injection.language)))
|
|
(text) @injection.content)
|
|
(#eq? @_attr "lang")
|
|
(#eq? @injection.language "pug")
|
|
(#set! injection.include-children))
|