mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-03 12:06:55 -04:00
cea9c5941d
This change conceals `full_reference_link`, `collapsed_reference_link`, and `shortcut_link` similarly to the `markdown_inline` query file already conceals `inline_link` and `image`. ## Test markdown contents ```markdown Some text before the link [full reference link text][link label] and now some text after the link onto a new line. Some text before the link [collapsed reference link text][] and now some text after the link onto a new line. Some text before the link [shortcut link text] and now some text after the link onto a new line. ``` ## Test markdown concealed screenshot Closes #3267
91 lines
1.3 KiB
Scheme
91 lines
1.3 KiB
Scheme
;; From MDeiml/tree-sitter-markdown
|
|
[
|
|
(code_span)
|
|
(link_title)
|
|
] @text.literal
|
|
|
|
[
|
|
(emphasis_delimiter)
|
|
(code_span_delimiter)
|
|
] @punctuation.delimiter
|
|
|
|
(emphasis) @text.emphasis
|
|
|
|
(strong_emphasis) @text.strong
|
|
|
|
[
|
|
(link_destination)
|
|
(uri_autolink)
|
|
] @text.uri
|
|
|
|
[
|
|
(link_label)
|
|
(link_text)
|
|
(image_description)
|
|
] @text.reference
|
|
|
|
[
|
|
(backslash_escape)
|
|
(hard_line_break)
|
|
] @string.escape
|
|
|
|
; "(" not part of query because of
|
|
; https://github.com/nvim-treesitter/nvim-treesitter/issues/2206
|
|
; TODO: Find better fix for this
|
|
(image ["!" "[" "]" "("] @punctuation.delimiter)
|
|
(inline_link ["[" "]" "("] @punctuation.delimiter)
|
|
(shortcut_link ["[" "]"] @punctuation.delimiter)
|
|
|
|
([
|
|
(code_span_delimiter)
|
|
(emphasis_delimiter)
|
|
] @conceal
|
|
(#set! conceal ""))
|
|
|
|
; Conceal inline links
|
|
(inline_link
|
|
[
|
|
"["
|
|
"]"
|
|
"("
|
|
(link_destination)
|
|
")"
|
|
] @conceal
|
|
(#set! conceal ""))
|
|
|
|
; Conceal image links
|
|
(image
|
|
[
|
|
"!"
|
|
"["
|
|
"]"
|
|
"("
|
|
(link_destination)
|
|
")"
|
|
] @conceal
|
|
(#set! conceal ""))
|
|
|
|
; Conceal full reference links
|
|
(full_reference_link
|
|
[
|
|
"["
|
|
"]"
|
|
(link_label)
|
|
] @conceal
|
|
(#set! conceal ""))
|
|
|
|
; Conceal collapsed reference links
|
|
(collapsed_reference_link
|
|
[
|
|
"["
|
|
"]"
|
|
] @conceal
|
|
(#set! conceal ""))
|
|
|
|
; Conceal shortcut links
|
|
(shortcut_link
|
|
[
|
|
"["
|
|
"]"
|
|
] @conceal
|
|
(#set! conceal ""))
|