mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-09 06:50:06 -04:00
add6f9abe2
There has been a lot of changes recently to the Scala grammar and we've been merging in a handful of things before syncing the actual generated parser. We are currently at a stage where we're going to sync everything, but there are some breaking changes that are included in https://github.com/tree-sitter/tree-sitter-scala/pull/135, so when that commit gets synced here stuff will break. We've taken the queries that existed here and have been building off of them in the actual upstream repo. This will hopefully make the transition smooth and updates the queries to ensure that there is no breakage. It's recommended to wait until that pr is merged, synced here, and then merge this in around the same time. Co-authored-by: eugene yokota <eed3si9n@gmail.com> Co-authored-by: Anton Sviridov <keynmol@gmail.com>
248 lines
3.9 KiB
Scheme
248 lines
3.9 KiB
Scheme
; CREDITS @stumash (stuart.mashaal@gmail.com)
|
|
|
|
(class_definition
|
|
name: (identifier) @type)
|
|
|
|
(enum_definition
|
|
name: (identifier) @type)
|
|
|
|
(object_definition
|
|
name: (identifier) @type)
|
|
|
|
(trait_definition
|
|
name: (identifier) @type)
|
|
|
|
(full_enum_case
|
|
name: (identifier) @type)
|
|
|
|
(simple_enum_case
|
|
name: (identifier) @type)
|
|
|
|
;; variables
|
|
|
|
(class_parameter
|
|
name: (identifier) @parameter)
|
|
|
|
|
|
(interpolation) @none
|
|
|
|
;; types
|
|
|
|
(type_definition
|
|
name: (type_identifier) @type.definition)
|
|
|
|
(type_identifier) @type
|
|
|
|
|
|
;; val/var definitions/declarations
|
|
|
|
(val_definition
|
|
pattern: (identifier) @variable)
|
|
|
|
(var_definition
|
|
pattern: (identifier) @variable)
|
|
|
|
(val_declaration
|
|
name: (identifier) @variable)
|
|
|
|
(var_declaration
|
|
name: (identifier) @variable)
|
|
|
|
; method definition
|
|
|
|
(function_declaration
|
|
name: (identifier) @method)
|
|
|
|
(function_definition
|
|
name: (identifier) @method)
|
|
|
|
; imports/exports
|
|
|
|
(import_declaration
|
|
path: (identifier) @namespace)
|
|
((stable_identifier (identifier) @namespace))
|
|
|
|
((import_declaration
|
|
path: (identifier) @type) (#lua-match? @type "^[A-Z]"))
|
|
((stable_identifier (identifier) @type) (#lua-match? @type "^[A-Z]"))
|
|
|
|
(export_declaration
|
|
path: (identifier) @namespace)
|
|
((stable_identifier (identifier) @namespace))
|
|
|
|
((export_declaration
|
|
path: (identifier) @type) (#lua-match? @type "^[A-Z]"))
|
|
((stable_identifier (identifier) @type) (#lua-match? @type "^[A-Z]"))
|
|
|
|
((namespace_selectors (identifier) @type) (#lua-match? @type "^[A-Z]"))
|
|
|
|
; method invocation
|
|
|
|
|
|
(call_expression
|
|
function: (identifier) @function.call)
|
|
|
|
(call_expression
|
|
function: (operator_identifier) @function.call)
|
|
|
|
(call_expression
|
|
function: (field_expression
|
|
field: (identifier) @method.call))
|
|
|
|
((call_expression
|
|
function: (identifier) @constructor)
|
|
(#lua-match? @constructor "^[A-Z]"))
|
|
|
|
(generic_function
|
|
function: (identifier) @function.call)
|
|
|
|
; function definitions
|
|
|
|
(function_definition
|
|
name: (identifier) @function)
|
|
|
|
(parameter
|
|
name: (identifier) @parameter)
|
|
|
|
; expressions
|
|
|
|
(field_expression field: (identifier) @property)
|
|
(field_expression value: (identifier) @type
|
|
(#lua-match? @type "^[A-Z]"))
|
|
|
|
(infix_expression operator: (identifier) @operator)
|
|
(infix_expression operator: (operator_identifier) @operator)
|
|
(infix_type operator: (operator_identifier) @operator)
|
|
(infix_type operator: (operator_identifier) @operator)
|
|
|
|
; literals
|
|
|
|
(boolean_literal) @boolean
|
|
(integer_literal) @number
|
|
(floating_point_literal) @float
|
|
|
|
[
|
|
(symbol_literal)
|
|
(string)
|
|
(character_literal)
|
|
(interpolated_string_expression)
|
|
] @string
|
|
|
|
(interpolation "$" @punctuation.special)
|
|
|
|
;; keywords
|
|
|
|
(opaque_modifier) @type.qualifier
|
|
(infix_modifier) @keyword
|
|
(transparent_modifier) @type.qualifier
|
|
(open_modifier) @type.qualifier
|
|
|
|
[
|
|
"case"
|
|
"class"
|
|
"enum"
|
|
"extends"
|
|
"derives"
|
|
"finally"
|
|
;; `forSome` existential types not implemented yet
|
|
;; `macro` not implemented yet
|
|
"object"
|
|
"override"
|
|
"package"
|
|
"trait"
|
|
"type"
|
|
"val"
|
|
"var"
|
|
"with"
|
|
"given"
|
|
"using"
|
|
"end"
|
|
"implicit"
|
|
"extension"
|
|
"with"
|
|
] @keyword
|
|
|
|
[
|
|
"abstract"
|
|
"final"
|
|
"lazy"
|
|
"sealed"
|
|
"private"
|
|
"protected"
|
|
] @type.qualifier
|
|
|
|
(inline_modifier) @storageclass
|
|
|
|
(null_literal) @constant.builtin
|
|
|
|
(wildcard) @parameter
|
|
|
|
(annotation) @attribute
|
|
|
|
;; special keywords
|
|
|
|
"new" @keyword.operator
|
|
|
|
[
|
|
"else"
|
|
"if"
|
|
"match"
|
|
"then"
|
|
] @conditional
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
"."
|
|
","
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"do"
|
|
"for"
|
|
"while"
|
|
"yield"
|
|
] @repeat
|
|
|
|
"def" @keyword.function
|
|
|
|
[
|
|
"=>"
|
|
"<-"
|
|
"@"
|
|
] @operator
|
|
|
|
["import" "export"] @include
|
|
|
|
[
|
|
"try"
|
|
"catch"
|
|
"throw"
|
|
] @exception
|
|
|
|
"return" @keyword.return
|
|
|
|
(comment) @comment @spell
|
|
|
|
;; `case` is a conditional keyword in case_block
|
|
|
|
(case_block
|
|
(case_clause ("case") @conditional))
|
|
|
|
(operator_identifier) @operator
|
|
|
|
((identifier) @constant (#lua-match? @constant "^[A-Z]"))
|
|
((identifier) @variable.builtin
|
|
(#lua-match? @variable.builtin "^this$"))
|
|
|
|
(
|
|
(identifier) @function.builtin
|
|
(#lua-match? @function.builtin "^super$")
|
|
)
|