mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 11:06:54 -04:00
9a51f860c1
Git config's sections, variable names, and (sometimes) subsections are case-insensitive. This commit proposes to match the full lowercase variants in addition to the non-normalised, lowerCamelCase ones. See `git help config`
69 lines
1.6 KiB
Scheme
69 lines
1.6 KiB
Scheme
((comment) @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
((variable
|
|
(name) @_name
|
|
value: (string) @injection.content)
|
|
(#any-of? @_name "cmd" "command" "textconv" "sendmailCmd" "sendmailcmd")
|
|
(#set! injection.language "bash"))
|
|
|
|
(section
|
|
(variable
|
|
(name) @_name
|
|
value: (string) @injection.content)
|
|
(#eq? @_name "tool")
|
|
(#set! injection.language "bash"))
|
|
|
|
(section
|
|
(section_header
|
|
(section_name) @_pager)
|
|
(variable
|
|
value: (string) @injection.content)
|
|
(#eq? @_pager "pager")
|
|
(#set! injection.language "bash"))
|
|
|
|
(section
|
|
(section_header
|
|
(section_name) @_interactive)
|
|
(variable
|
|
(name) @_name
|
|
value: (string) @injection.content)
|
|
(#eq? @_interactive "interactive")
|
|
(#any-of? @_name "diffFilter" "difffilter")
|
|
(#set! injection.language "bash"))
|
|
|
|
; https://github.com/git-lfs/git-lfs
|
|
; git lfs install
|
|
(section
|
|
(section_header
|
|
(section_name) @_filter
|
|
(subsection_name) @_lfs)
|
|
(variable
|
|
(name) @_name
|
|
value: (string) @injection.content)
|
|
(#eq? @_filter "filter")
|
|
(#eq? @_lfs "lfs")
|
|
(#any-of? @_name "smudge" "process" "clean")
|
|
(#set! injection.language "bash"))
|
|
|
|
(section
|
|
(section_header
|
|
(section_name) @_alias)
|
|
(variable
|
|
value: (string) @injection.content)
|
|
(#eq? @_alias "alias")
|
|
(#lua-match? @injection.content "^!")
|
|
(#offset! @injection.content 0 1 0 0)
|
|
(#set! injection.language "bash"))
|
|
|
|
(section
|
|
(section_header
|
|
(section_name) @_alias)
|
|
(variable
|
|
value: (string
|
|
"\""
|
|
"\"") @injection.content)
|
|
(#eq? @_alias "alias")
|
|
(#lua-match? @injection.content "^\"!")
|
|
(#offset! @injection.content 0 2 0 -1)
|
|
(#set! injection.language "bash"))
|