mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-06 13:30:01 -04:00
78b54eb7f6
Since 0.9, @lang syntax is still available as fallback but will soon be deprecated. Because of that, new syntax should be adopted once 0.9 becomes the baseline requirements for nvim-treesitter - update health check - update doc
26 lines
654 B
Scheme
26 lines
654 B
Scheme
;; Inject markdown in docstrings
|
|
((string_literal) @injection.content
|
|
. [
|
|
(module_definition)
|
|
(abstract_definition)
|
|
(struct_definition)
|
|
(function_definition)
|
|
(short_function_definition)
|
|
(assignment)
|
|
(const_statement)
|
|
]
|
|
(#lua-match? @injection.content "^\"\"\"")
|
|
(#set! injection.language "markdown")
|
|
(#offset! @injection.content 0 3 0 -3))
|
|
|
|
([
|
|
(line_comment)
|
|
(block_comment)
|
|
] @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
((prefixed_string_literal
|
|
prefix: (identifier) @_prefix) @injection.content
|
|
(#eq? @_prefix "r")
|
|
(#set! injection.language "regex")
|
|
(#offset! @injection.content 0 2 0 -1))
|