mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-05 04:50:03 -04:00
64b3d5e569
Add parser `php_only` for PHP files without HTML embedded. Make queries for combined parser `php` inherit from `php_only` (no extensions needed). --------- Co-authored-by: shirasaka <tk.shirasaka@gmail>
43 lines
1.1 KiB
Scheme
43 lines
1.1 KiB
Scheme
((comment) @injection.content
|
|
(#set! injection.language "phpdoc"))
|
|
|
|
((heredoc
|
|
(heredoc_body) @injection.content
|
|
(heredoc_end) @injection.language
|
|
(#set! injection.include-children)
|
|
(#downcase! @injection.language)))
|
|
|
|
((nowdoc
|
|
(nowdoc_body) @injection.content
|
|
(heredoc_end) @injection.language
|
|
(#set! injection.include-children)
|
|
(#downcase! @injection.language)))
|
|
|
|
; regex
|
|
((function_call_expression
|
|
function: (_) @_preg_func_identifier
|
|
arguments:
|
|
(arguments
|
|
.
|
|
(argument
|
|
(_
|
|
(string_value) @injection.content))))
|
|
(#set! injection.language "regex")
|
|
(#lua-match? @_preg_func_identifier "^preg_"))
|
|
|
|
; bash
|
|
((function_call_expression
|
|
function: (_) @_shell_func_identifier
|
|
arguments:
|
|
(arguments
|
|
.
|
|
(argument
|
|
(_
|
|
(string_value) @injection.content))))
|
|
(#set! injection.language "bash")
|
|
(#any-of? @_shell_func_identifier "shell_exec" "escapeshellarg" "escapeshellcmd" "exec" "passthru" "proc_open" "shell_exec" "system"))
|
|
|
|
(expression_statement
|
|
(shell_command_expression
|
|
(string_value) @injection.content)
|
|
(#set! injection.language "bash"))
|