mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
118 lines
1.5 KiB
Scheme
118 lines
1.5 KiB
Scheme
(id) @variable
|
|
(comment) @comment @spell
|
|
|
|
; Literals
|
|
(null) @constant.builtin
|
|
(string) @string
|
|
(number) @number
|
|
[
|
|
(true)
|
|
(false)
|
|
] @boolean
|
|
|
|
; Keywords
|
|
"for" @keyword.repeat
|
|
"in" @keyword.operator
|
|
"function" @keyword.function
|
|
|
|
[
|
|
"if"
|
|
"then"
|
|
"else"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
(local)
|
|
(tailstrict)
|
|
"function"
|
|
] @keyword
|
|
|
|
[
|
|
"assert"
|
|
"error"
|
|
] @keyword.exception
|
|
|
|
[
|
|
(dollar)
|
|
(self)
|
|
(super)
|
|
] @variable.builtin
|
|
((id) @variable.builtin
|
|
(#eq? @variable.builtin "std"))
|
|
|
|
; Operators
|
|
[
|
|
(multiplicative)
|
|
(additive)
|
|
(bitshift)
|
|
(comparison)
|
|
(equality)
|
|
(bitand)
|
|
(bitxor)
|
|
(bitor)
|
|
(and)
|
|
(or)
|
|
(unaryop)
|
|
] @operator
|
|
|
|
; Punctuation
|
|
[
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
"("
|
|
")"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
"."
|
|
","
|
|
";"
|
|
":"
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"::"
|
|
":::"
|
|
] @punctuation.special
|
|
|
|
(field
|
|
(fieldname) "+" @punctuation.special)
|
|
|
|
; Imports
|
|
[
|
|
(import)
|
|
(importstr)
|
|
] @keyword.import
|
|
|
|
; Fields
|
|
|
|
(fieldname (id) @variable.member)
|
|
(fieldname (string (string_content) @variable.member))
|
|
|
|
; Functions
|
|
(field
|
|
function: (fieldname (id) @function))
|
|
(field
|
|
function: (fieldname
|
|
(string (string_content) @function)))
|
|
(param
|
|
identifier: (id) @variable.parameter)
|
|
|
|
(bind (id) @variable.local)
|
|
(bind function: (id) @function)
|
|
|
|
; Function call
|
|
(functioncall
|
|
(fieldaccess
|
|
last: (id) @function.call)?
|
|
(fieldaccess_super
|
|
(id) @function.call)?
|
|
(id)? @function.call
|
|
"("
|
|
(args
|
|
(named_argument
|
|
(id) @variable.parameter
|
|
))?
|
|
")")
|