mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
95 lines
1.6 KiB
Scheme
95 lines
1.6 KiB
Scheme
(unit
|
|
(identifier) @variable)
|
|
(string
|
|
(identifier) @variable)
|
|
|
|
(escape_sequence) @string.escape
|
|
|
|
(block
|
|
(unit
|
|
(identifier) @module))
|
|
|
|
(func
|
|
(identifier) @function)
|
|
|
|
(number) @number
|
|
|
|
((identifier) @boolean
|
|
(#any-of? @boolean "true" "false" "True" "False"))
|
|
|
|
((identifier) @constant
|
|
(#lua-match? @constant "^[A-Z][A-Z%d_]*$"))
|
|
|
|
((identifier) @constant.builtin
|
|
(#eq? @constant.builtin "null"))
|
|
|
|
((identifier) @type
|
|
(#any-of? @type
|
|
"String"
|
|
"Map"
|
|
"Object"
|
|
"Boolean"
|
|
"Integer"
|
|
"List"))
|
|
|
|
((identifier) @function.builtin
|
|
(#any-of? @function.builtin
|
|
"void"
|
|
"id"
|
|
"version"
|
|
"apply"
|
|
"implementation"
|
|
"testImplementation"
|
|
"androidTestImplementation"
|
|
"debugImplementation"))
|
|
|
|
((identifier) @keyword
|
|
(#any-of? @keyword
|
|
"static"
|
|
"class"
|
|
"def"
|
|
"import"
|
|
"package"
|
|
"assert"
|
|
"extends"
|
|
"implements"
|
|
"instanceof"
|
|
"interface"
|
|
"new"))
|
|
|
|
((identifier) @type.qualifier
|
|
(#any-of? @type.qualifier
|
|
"abstract"
|
|
"protected"
|
|
"private"
|
|
"public"))
|
|
|
|
((identifier) @keyword.exception
|
|
(#any-of? @keyword.exception
|
|
"throw"
|
|
"finally"
|
|
"try"
|
|
"catch"))
|
|
|
|
(string) @string
|
|
|
|
[
|
|
(line_comment)
|
|
(block_comment)
|
|
] @comment @spell
|
|
|
|
((block_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^/[*][*][^*].*[*]/$"))
|
|
|
|
((line_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///[^/]"))
|
|
|
|
((line_comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^///$"))
|
|
|
|
[
|
|
(operators)
|
|
(leading_key)
|
|
] @operator
|
|
|
|
["(" ")" "[" "]" "{" "}"] @punctuation.bracket
|