mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
79 lines
1.9 KiB
Scheme
79 lines
1.9 KiB
Scheme
(
|
|
(function_declaration
|
|
name: (identifier) @local.definition.function) ;@function
|
|
)
|
|
|
|
(
|
|
(method_declaration
|
|
name: (field_identifier) @local.definition.method); @function.method
|
|
)
|
|
|
|
(short_var_declaration
|
|
left: (expression_list
|
|
(identifier) @local.definition.var))
|
|
|
|
(var_spec
|
|
name: (identifier) @local.definition.var)
|
|
|
|
(parameter_declaration (identifier) @local.definition.var)
|
|
(variadic_parameter_declaration (identifier) @local.definition.var)
|
|
|
|
(for_statement
|
|
(range_clause
|
|
left: (expression_list
|
|
(identifier) @local.definition.var)))
|
|
|
|
(const_declaration
|
|
(const_spec
|
|
name: (identifier) @local.definition.var))
|
|
|
|
(type_declaration
|
|
(type_spec
|
|
name: (type_identifier) @local.definition.type))
|
|
|
|
;; reference
|
|
(identifier) @local.reference
|
|
(type_identifier) @local.reference
|
|
(field_identifier) @local.reference
|
|
((package_identifier) @local.reference
|
|
(#set! reference.kind "namespace"))
|
|
|
|
(package_clause
|
|
(package_identifier) @local.definition.namespace)
|
|
|
|
(import_spec_list
|
|
(import_spec
|
|
name: (package_identifier) @local.definition.namespace))
|
|
|
|
;; Call references
|
|
((call_expression
|
|
function: (identifier) @local.reference)
|
|
(#set! reference.kind "call" ))
|
|
|
|
((call_expression
|
|
function: (selector_expression
|
|
field: (field_identifier) @local.reference))
|
|
(#set! reference.kind "call" ))
|
|
|
|
|
|
((call_expression
|
|
function: (parenthesized_expression
|
|
(identifier) @local.reference))
|
|
(#set! reference.kind "call" ))
|
|
|
|
((call_expression
|
|
function: (parenthesized_expression
|
|
(selector_expression
|
|
field: (field_identifier) @local.reference)))
|
|
(#set! reference.kind "call" ))
|
|
|
|
;; Scopes
|
|
|
|
(func_literal) @local.scope
|
|
(source_file) @local.scope
|
|
(function_declaration) @local.scope
|
|
(if_statement) @local.scope
|
|
(block) @local.scope
|
|
(expression_switch_statement) @local.scope
|
|
(for_statement) @local.scope
|
|
(method_declaration) @local.scope
|