mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
88 lines
2.4 KiB
Scheme
88 lines
2.4 KiB
Scheme
; === Tag Names ===
|
|
|
|
; Tags that start with a lower case letter are HTML tags
|
|
; We'll also use this highlighting for named blocks (which start with `:`)
|
|
((tag_name) @tag
|
|
(#lua-match? @tag "^:?[%l]"))
|
|
; Tags that start with a capital letter are Glimmer components
|
|
((tag_name) @constructor
|
|
(#lua-match? @constructor "^%u"))
|
|
|
|
(attribute_name) @property
|
|
|
|
(string_literal) @string
|
|
(number_literal) @number
|
|
(boolean_literal) @boolean
|
|
|
|
(concat_statement) @string
|
|
|
|
; === Block Statements ===
|
|
|
|
; Highlight the brackets
|
|
(block_statement_start) @tag.delimiter
|
|
(block_statement_end) @tag.delimiter
|
|
|
|
; Highlight `if`/`each`/`let`
|
|
(block_statement_start path: (identifier) @keyword.conditional)
|
|
(block_statement_end path: (identifier) @keyword.conditional)
|
|
((mustache_statement (identifier) @keyword.conditional)
|
|
(#lua-match? @keyword.conditional "else"))
|
|
|
|
; == Mustache Statements ===
|
|
|
|
; Highlight the whole statement, to color brackets and separators
|
|
(mustache_statement) @tag.delimiter
|
|
|
|
; An identifier in a mustache expression is a variable
|
|
((mustache_statement [
|
|
(path_expression (identifier) @variable)
|
|
(identifier) @variable
|
|
])
|
|
(#not-any-of? @variable "yield" "outlet" "this" "else"))
|
|
; As are arguments in a block statement
|
|
(block_statement_start argument: [
|
|
(path_expression (identifier) @variable)
|
|
(identifier) @variable
|
|
])
|
|
; As is an identifier in a block param
|
|
(block_params (identifier) @variable)
|
|
; As are helper arguments
|
|
((helper_invocation argument: [
|
|
(path_expression (identifier) @variable)
|
|
(identifier) @variable
|
|
])
|
|
(#not-eq? @variable "this"))
|
|
; `this` should be highlighted as a built-in variable
|
|
((identifier) @variable.builtin
|
|
(#eq? @variable.builtin "this"))
|
|
|
|
; If the identifier is just "yield" or "outlet", it's a keyword
|
|
((mustache_statement (identifier) @keyword)
|
|
(#any-of? @keyword "yield" "outlet"))
|
|
|
|
; Helpers are functions
|
|
((helper_invocation helper: [
|
|
(path_expression (identifier) @function)
|
|
(identifier) @function
|
|
])
|
|
(#not-any-of? @function "if" "yield"))
|
|
((helper_invocation helper: (identifier) @keyword.conditional)
|
|
(#eq? @keyword.conditional "if"))
|
|
((helper_invocation helper: (identifier) @keyword)
|
|
(#eq? @keyword "yield"))
|
|
|
|
(hash_pair key: (identifier) @property)
|
|
|
|
(comment_statement) @comment @spell
|
|
|
|
(attribute_node "=" @operator)
|
|
|
|
(block_params "as" @keyword)
|
|
(block_params "|" @operator)
|
|
|
|
[
|
|
"<"
|
|
">"
|
|
"</"
|
|
"/>"
|
|
] @tag.delimiter
|