mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
169 lines
2.5 KiB
Scheme
169 lines
2.5 KiB
Scheme
; Keywords
|
|
[
|
|
"as"
|
|
"let"
|
|
"panic"
|
|
"todo"
|
|
"type"
|
|
"use"
|
|
] @keyword
|
|
|
|
; Function Keywords
|
|
[
|
|
"fn"
|
|
] @keyword.function
|
|
|
|
; Imports
|
|
[
|
|
"import"
|
|
] @keyword.import
|
|
|
|
; Conditionals
|
|
[
|
|
"case"
|
|
"if"
|
|
] @keyword.conditional
|
|
|
|
; Exceptions
|
|
[
|
|
"assert"
|
|
] @keyword.exception
|
|
|
|
; Punctuation
|
|
[
|
|
"("
|
|
")"
|
|
"<<"
|
|
">>"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
","
|
|
"."
|
|
":"
|
|
"->"
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"#"
|
|
] @punctuation.special
|
|
|
|
; Operators
|
|
[
|
|
"%"
|
|
"&&"
|
|
"*"
|
|
"*."
|
|
"+"
|
|
"+."
|
|
"-"
|
|
"-."
|
|
".."
|
|
"/"
|
|
"/."
|
|
"<"
|
|
"<."
|
|
"<="
|
|
"<=."
|
|
"="
|
|
"=="
|
|
">"
|
|
">."
|
|
">="
|
|
">=."
|
|
"|>"
|
|
"||"
|
|
] @operator
|
|
|
|
; Identifiers
|
|
(identifier) @variable
|
|
|
|
; Comments
|
|
[
|
|
(comment)
|
|
] @comment @spell
|
|
|
|
[
|
|
(module_comment)
|
|
(statement_comment)
|
|
] @comment.documentation @spell
|
|
|
|
; Unused Identifiers
|
|
[
|
|
(discard)
|
|
(hole)
|
|
] @comment
|
|
|
|
; Modules & Imports
|
|
(module) @module
|
|
(import alias: ((identifier) @module)?)
|
|
(remote_type_identifier module: (identifier) @module)
|
|
(unqualified_import name: (identifier) @function)
|
|
|
|
; Strings
|
|
(string) @string
|
|
|
|
; Bit Strings
|
|
(bit_string_segment) @string.special
|
|
|
|
; Numbers
|
|
(integer) @number
|
|
|
|
(float) @number.float
|
|
|
|
; Function Parameter Labels
|
|
(function_call arguments: (arguments (argument label: (label) @label)))
|
|
(function_parameter label: (label)? @label name: (identifier) @variable.parameter)
|
|
|
|
; Records
|
|
(record arguments: (arguments (argument label: (label) @property)?))
|
|
(record_pattern_argument label: (label) @property)
|
|
(record_update_argument label: (label) @property)
|
|
(field_access record: (identifier) @variable field: (label) @property)
|
|
(data_constructor_argument (label) @property)
|
|
|
|
; Types
|
|
[
|
|
(type_identifier)
|
|
(type_parameter)
|
|
(type_var)
|
|
] @type
|
|
|
|
((type_identifier) @type.builtin
|
|
(#any-of? @type.builtin "Int" "Float" "String" "List"))
|
|
|
|
; Type Qualifiers
|
|
[
|
|
"const"
|
|
"external"
|
|
(opacity_modifier)
|
|
(visibility_modifier)
|
|
] @type.qualifier
|
|
|
|
; Tuples
|
|
(tuple_access index: (integer) @operator)
|
|
|
|
; Functions
|
|
(function name: (identifier) @function)
|
|
(function_call function: (identifier) @function.call)
|
|
(function_call function: (field_access field: (label) @function.call))
|
|
|
|
; External Functions
|
|
(external_function name: (identifier) @function)
|
|
(external_function_body (string) @module . (string) @function)
|
|
|
|
; Constructors
|
|
(constructor_name) @type @constructor
|
|
|
|
([(type_identifier) (constructor_name)] @constant.builtin
|
|
(#any-of? @constant.builtin "Ok" "Error"))
|
|
|
|
; Booleans
|
|
((constructor_name) @boolean (#any-of? @boolean "True" "False"))
|
|
|
|
; Pipe Operator
|
|
(binary_expression operator: "|>" right: (identifier) @function)
|