mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
121 lines
2.1 KiB
Scheme
121 lines
2.1 KiB
Scheme
(comment) @comment @spell
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
] @punctuation.bracket
|
|
|
|
[
|
|
":"
|
|
":until"
|
|
"&"
|
|
"&as"
|
|
"?"
|
|
] @punctuation.special
|
|
|
|
(nil) @constant.builtin
|
|
(vararg) @punctuation.special
|
|
|
|
(boolean) @boolean
|
|
(number) @number
|
|
|
|
(string) @string
|
|
(escape_sequence) @string.escape
|
|
|
|
(symbol) @variable
|
|
|
|
(multi_symbol
|
|
"." @punctuation.delimiter
|
|
(symbol) @variable.member)
|
|
|
|
(multi_symbol_method
|
|
":" @punctuation.delimiter
|
|
(symbol) @function.method.call .)
|
|
|
|
(list . (symbol) @function.call)
|
|
(list . (multi_symbol (symbol) @function.call .))
|
|
|
|
((symbol) @variable.builtin
|
|
(#lua-match? @variable.builtin "^[$]"))
|
|
|
|
(binding) @string.special.symbol
|
|
|
|
[
|
|
"fn"
|
|
"lambda"
|
|
"hashfn"
|
|
"#"
|
|
] @keyword.function
|
|
|
|
(fn name: [
|
|
(symbol) @function
|
|
(multi_symbol (symbol) @function .)
|
|
])
|
|
|
|
(lambda name: [
|
|
(symbol) @function
|
|
(multi_symbol (symbol) @function .)
|
|
])
|
|
|
|
[
|
|
"for"
|
|
"each"
|
|
] @keyword.repeat
|
|
((symbol) @keyword.repeat
|
|
(#any-of? @keyword.repeat
|
|
"while"))
|
|
|
|
[
|
|
"match"
|
|
] @keyword.conditional
|
|
((symbol) @keyword.conditional
|
|
(#any-of? @keyword.conditional
|
|
"if" "when"))
|
|
|
|
[
|
|
"global"
|
|
"local"
|
|
"let"
|
|
"set"
|
|
"var"
|
|
"where"
|
|
"or"
|
|
] @keyword
|
|
((symbol) @keyword
|
|
(#any-of? @keyword
|
|
"comment" "do" "doc" "eval-compiler" "lua" "macros" "quote" "tset" "values"))
|
|
|
|
((symbol) @keyword.import
|
|
(#any-of? @keyword.import
|
|
"require" "require-macros" "import-macros" "include"))
|
|
|
|
[
|
|
"collect"
|
|
"icollect"
|
|
"accumulate"
|
|
] @function.macro
|
|
|
|
((symbol) @function.macro
|
|
(#any-of? @function.macro
|
|
"->" "->>" "-?>" "-?>>" "?." "doto" "macro" "macrodebug" "partial" "pick-args"
|
|
"pick-values" "with-open"))
|
|
|
|
; Lua builtins
|
|
((symbol) @constant.builtin
|
|
(#any-of? @constant.builtin
|
|
"arg" "_ENV" "_G" "_VERSION"))
|
|
|
|
((symbol) @function.builtin
|
|
(#any-of? @function.builtin
|
|
"assert" "collectgarbage" "dofile" "error" "getmetatable" "ipairs"
|
|
"load" "loadfile" "next" "pairs" "pcall" "print" "rawequal" "rawget"
|
|
"rawlen" "rawset" "require" "select" "setmetatable" "tonumber" "tostring"
|
|
"type" "warn" "xpcall"))
|
|
|
|
((symbol) @function.builtin
|
|
(#any-of? @function.builtin
|
|
"loadstring" "module" "setfenv" "unpack"))
|