mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
130 lines
2.2 KiB
Scheme
130 lines
2.2 KiB
Scheme
((atom) @constant (#set! "priority" "90"))
|
|
(var) @variable
|
|
|
|
(char) @character
|
|
(integer) @number
|
|
(float) @number.float
|
|
|
|
(comment) @comment @spell
|
|
|
|
((comment) @comment.documentation
|
|
(#lua-match? @comment.documentation "^[%%][%%]"))
|
|
|
|
;; keyword
|
|
[
|
|
"fun"
|
|
"div"
|
|
] @keyword
|
|
|
|
;; bracket
|
|
[
|
|
"("
|
|
")"
|
|
"{"
|
|
"}"
|
|
"["
|
|
"]"
|
|
"#"
|
|
] @punctuation.bracket
|
|
|
|
;;; Comparisons
|
|
[
|
|
"=="
|
|
"=:="
|
|
"=/="
|
|
"=<"
|
|
">="
|
|
"<"
|
|
">"
|
|
] @operator ;; .comparison
|
|
|
|
;;; operator
|
|
[
|
|
":"
|
|
":="
|
|
"!"
|
|
;; "-"
|
|
"+"
|
|
"="
|
|
"->"
|
|
"=>"
|
|
"|"
|
|
"?="
|
|
] @operator
|
|
|
|
[
|
|
","
|
|
"."
|
|
";"
|
|
] @punctuation.delimiter
|
|
|
|
;; conditional
|
|
[
|
|
"receive"
|
|
"if"
|
|
"case"
|
|
"of"
|
|
"when"
|
|
"after"
|
|
"begin"
|
|
"end"
|
|
"maybe"
|
|
"else"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
"catch"
|
|
"try"
|
|
] @keyword.exception
|
|
|
|
((atom) @boolean (#any-of? @boolean "true" "false"))
|
|
|
|
;; Macros
|
|
((macro_call_expr) @constant.macro (#set! "priority" 101))
|
|
|
|
;; Preprocessor
|
|
(pp_define
|
|
lhs: _ @constant.macro (#set! "priority" 101)
|
|
)
|
|
(_preprocessor_directive) @keyword.directive (#set! "priority" 99)
|
|
|
|
;; Attributes
|
|
(pp_include) @keyword.import
|
|
(pp_include_lib) @keyword.import
|
|
(export_attribute) @keyword.import
|
|
(export_type_attribute) @type.definition
|
|
(export_type_attribute types: (fa fun: _ @type (#set! "priority" 101)))
|
|
(behaviour_attribute) @keyword.import
|
|
(module_attribute (atom) @module) @keyword.import
|
|
(wild_attribute name: (attr_name name: _ @attribute)) @attribute
|
|
|
|
;; Records
|
|
(record_expr) @type
|
|
(record_field_expr _ @variable.member) @type
|
|
(record_field_name _ @variable.member) @type
|
|
(record_name "#" @type name: _ @type) @type
|
|
(record_decl name: _ @type) @type.definition
|
|
(record_field name: _ @variable.member)
|
|
(record_field name: _ @variable.member ty: _ @type)
|
|
|
|
;; Type alias
|
|
(type_alias name: _ @type) @type.definition
|
|
(spec) @type.definition
|
|
|
|
[(string) (binary)] @string
|
|
|
|
;;; expr_function_call
|
|
(call expr: [(atom) (remote) (var)] @function)
|
|
(call (atom) @keyword.exception (#any-of? @keyword.exception "error" "throw" "exit"))
|
|
|
|
;;; Parenthesized expression: (SomeFunc)(), only highlight the parens
|
|
(call
|
|
expr: (paren_expr "(" @function.call ")" @function.call)
|
|
)
|
|
|
|
;;; function
|
|
(external_fun) @function.call
|
|
(internal_fun fun: (atom) @function.call)
|
|
(function_clause name: (atom) @function)
|
|
(fa fun: (atom) @function)
|
|
|