mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
119 lines
1.8 KiB
Scheme
119 lines
1.8 KiB
Scheme
;; XML declaration
|
|
|
|
(XMLDecl "xml" @keyword.directive)
|
|
|
|
(XMLDecl [ "version" "encoding" ] @tag.attribute)
|
|
|
|
(XMLDecl (EncName) @string.special)
|
|
|
|
(XMLDecl (VersionNum) @number)
|
|
|
|
;; Processing instructions
|
|
|
|
(PI) @keyword.directive
|
|
|
|
;; Element declaration
|
|
|
|
(elementdecl
|
|
"ELEMENT" @keyword.directive.define
|
|
(Name) @tag)
|
|
|
|
(contentspec
|
|
(_ (Name) @tag.attribute))
|
|
|
|
"#PCDATA" @type.builtin
|
|
|
|
[ "EMPTY" "ANY" ] @type.qualifier
|
|
|
|
[ "*" "?" "+" ] @character.special
|
|
|
|
;; Entity declaration
|
|
|
|
(GEDecl
|
|
"ENTITY" @keyword.directive.define
|
|
(Name) @constant)
|
|
|
|
(GEDecl (EntityValue) @string)
|
|
|
|
(NDataDecl
|
|
"NDATA" @keyword
|
|
(Name) @label)
|
|
|
|
;; Parsed entity declaration
|
|
|
|
(PEDecl
|
|
"ENTITY" @keyword.directive.define
|
|
"%" @operator
|
|
(Name) @function.macro)
|
|
|
|
(PEDecl (EntityValue) @string)
|
|
|
|
;; Notation declaration
|
|
|
|
(NotationDecl
|
|
"NOTATION" @keyword.directive
|
|
(Name) @label)
|
|
|
|
((NotationDecl
|
|
(ExternalID
|
|
(SystemLiteral (URI) @string.special.url))
|
|
(#set! "priority" 105)))
|
|
|
|
;; Attlist declaration
|
|
|
|
(AttlistDecl
|
|
"ATTLIST" @keyword.directive.define
|
|
(Name) @tag)
|
|
|
|
(AttDef (Name) @tag.attribute)
|
|
|
|
(AttDef (Enumeration (Nmtoken) @string))
|
|
|
|
[
|
|
(StringType)
|
|
(TokenizedType)
|
|
] @type.builtin
|
|
|
|
(NotationType "NOTATION" @type.builtin)
|
|
|
|
[
|
|
"#REQUIRED"
|
|
"#IMPLIED"
|
|
"#FIXED"
|
|
] @attribute
|
|
|
|
;; Entities
|
|
|
|
(EntityRef) @constant
|
|
|
|
((EntityRef) @constant.builtin
|
|
(#any-of? @constant.builtin
|
|
"&" "<" ">" """ "'"))
|
|
|
|
(CharRef) @character
|
|
|
|
(PEReference) @function.macro
|
|
|
|
;; External references
|
|
|
|
[ "PUBLIC" "SYSTEM" ] @keyword
|
|
|
|
(PubidLiteral) @string.special
|
|
|
|
(SystemLiteral (URI) @string.special.url)
|
|
|
|
;; Delimiters & punctuation
|
|
|
|
[ "<?" "?>" "<!" ">" "]]>" ] @tag.delimiter
|
|
|
|
[ "(" ")" "[" ] @punctuation.bracket
|
|
|
|
[ "\"" "'" ] @punctuation.delimiter
|
|
|
|
[ "," "|" "=" ] @operator
|
|
|
|
;; Misc
|
|
|
|
[ "INCLUDE" "IGNORE" ] @keyword.import
|
|
|
|
(Comment) @comment @spell
|