mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
160 lines
1.8 KiB
Scheme
160 lines
1.8 KiB
Scheme
; Includes
|
|
|
|
[
|
|
"package"
|
|
"import"
|
|
] @keyword.import
|
|
|
|
; Namespaces
|
|
|
|
(package_identifier) @module
|
|
|
|
(import_spec ["." "_"] @punctuation.special)
|
|
|
|
[
|
|
(attr_path)
|
|
(package_path)
|
|
] @string.special.url ;; In attributes
|
|
|
|
; Attributes
|
|
|
|
(attribute) @attribute
|
|
|
|
; Conditionals
|
|
|
|
"if" @keyword.conditional
|
|
|
|
; Repeats
|
|
|
|
[
|
|
"for"
|
|
] @keyword.repeat
|
|
|
|
(for_clause "_" @punctuation.special)
|
|
|
|
; Keywords
|
|
|
|
[
|
|
"let"
|
|
] @keyword
|
|
|
|
[
|
|
"in"
|
|
] @keyword.operator
|
|
|
|
; Operators
|
|
|
|
[
|
|
"+"
|
|
"-"
|
|
"*"
|
|
"/"
|
|
"|"
|
|
"&"
|
|
"||"
|
|
"&&"
|
|
"=="
|
|
"!="
|
|
"<"
|
|
"<="
|
|
">"
|
|
">="
|
|
"=~"
|
|
"!~"
|
|
"!"
|
|
"="
|
|
] @operator
|
|
|
|
; Fields & Properties
|
|
|
|
(field
|
|
(label
|
|
(identifier) @variable.member))
|
|
|
|
(selector_expression
|
|
(_)
|
|
(identifier) @property)
|
|
|
|
; Functions
|
|
|
|
(call_expression
|
|
function: (identifier) @function.call)
|
|
(call_expression
|
|
function: (selector_expression
|
|
(_)
|
|
(identifier) @function.call))
|
|
(call_expression
|
|
function: (builtin_function) @function.call)
|
|
|
|
(builtin_function) @function.builtin
|
|
|
|
; Variables
|
|
|
|
(identifier) @variable
|
|
|
|
; Types
|
|
|
|
(primitive_type) @type.builtin
|
|
|
|
((identifier) @type
|
|
(#lua-match? @type "^_?#"))
|
|
|
|
[
|
|
(slice_type)
|
|
(pointer_type)
|
|
] @type ;; In attributes
|
|
|
|
; Punctuation
|
|
|
|
[
|
|
","
|
|
":"
|
|
] @punctuation.delimiter
|
|
|
|
[ "{" "}" ] @punctuation.bracket
|
|
|
|
[ "[" "]" ] @punctuation.bracket
|
|
|
|
[ "(" ")" ] @punctuation.bracket
|
|
|
|
[ "<" ">" ] @punctuation.bracket
|
|
|
|
[
|
|
(ellipsis)
|
|
"?"
|
|
] @punctuation.special
|
|
|
|
; Literals
|
|
|
|
(string) @string
|
|
|
|
[
|
|
(escape_char)
|
|
(escape_unicode)
|
|
] @string.escape
|
|
|
|
(number) @number
|
|
|
|
(float) @number.float
|
|
|
|
(si_unit
|
|
(float)
|
|
(_) @string.special.symbol)
|
|
|
|
(boolean) @boolean
|
|
|
|
[
|
|
(null)
|
|
(top)
|
|
(bottom)
|
|
] @constant.builtin
|
|
|
|
; Interpolations
|
|
|
|
(interpolation "\\(" @punctuation.special (_) ")" @punctuation.special) @none
|
|
|
|
(interpolation "\\(" (identifier) @variable ")")
|
|
|
|
; Comments
|
|
|
|
(comment) @comment @spell
|