mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
195 lines
2.6 KiB
Scheme
195 lines
2.6 KiB
Scheme
; adapted from https://github.com/Beaglefoot/tree-sitter-awk
|
|
|
|
[
|
|
(identifier)
|
|
(field_ref)
|
|
] @variable
|
|
(field_ref (_) @variable)
|
|
|
|
; https://www.gnu.org/software/gawk/manual/html_node/Auto_002dset.html
|
|
((identifier) @constant.builtin
|
|
(#any-of? @constant.builtin
|
|
"ARGC"
|
|
"ARGV"
|
|
"ARGIND"
|
|
"ENVIRON"
|
|
"ERRNO"
|
|
"FILENAME"
|
|
"FNR"
|
|
"NF"
|
|
"FUNCTAB"
|
|
"NR"
|
|
"PROCINFO"
|
|
"RLENGTH"
|
|
"RSTART"
|
|
"RT"
|
|
"SYMTAB"))
|
|
|
|
; https://www.gnu.org/software/gawk/manual/html_node/User_002dmodified.html
|
|
((identifier) @variable.builtin
|
|
(#any-of? @variable.builtin
|
|
"BINMODE"
|
|
"CONVFMT"
|
|
"FIELDWIDTHS"
|
|
"FPAT"
|
|
"FS"
|
|
"IGNORECASE"
|
|
"LINT"
|
|
"OFMT"
|
|
"OFS"
|
|
"ORS"
|
|
"PREC"
|
|
"ROUNDMODE"
|
|
"RS"
|
|
"SUBSEP"
|
|
"TEXTDOMAIN"))
|
|
|
|
(number) @number
|
|
|
|
(string) @string
|
|
(regex) @string.regexp
|
|
(escape_sequence) @string.escape
|
|
|
|
(comment) @comment @spell
|
|
|
|
((program . (comment) @keyword.directive)
|
|
(#lua-match? @keyword.directive "^#!/"))
|
|
|
|
(ns_qualified_name (namespace) @module)
|
|
(ns_qualified_name "::" @punctuation.delimiter)
|
|
|
|
(func_def name: (_ (identifier) @function) @function)
|
|
(func_call name: (_ (identifier) @function) @function)
|
|
|
|
(func_def (param_list (identifier) @variable.parameter))
|
|
|
|
[
|
|
"print"
|
|
"printf"
|
|
"getline"
|
|
] @function.builtin
|
|
|
|
[
|
|
(delete_statement)
|
|
(break_statement)
|
|
(continue_statement)
|
|
(next_statement)
|
|
(nextfile_statement)
|
|
] @keyword
|
|
|
|
[
|
|
"func"
|
|
"function"
|
|
] @keyword.function
|
|
|
|
[
|
|
"return"
|
|
"exit"
|
|
] @keyword.return
|
|
|
|
[
|
|
"do"
|
|
"while"
|
|
"for"
|
|
"in"
|
|
] @keyword.repeat
|
|
|
|
[
|
|
"if"
|
|
"else"
|
|
"switch"
|
|
"case"
|
|
"default"
|
|
] @keyword.conditional
|
|
|
|
[
|
|
"@include"
|
|
"@load"
|
|
] @keyword.import
|
|
|
|
"@namespace" @keyword.directive
|
|
|
|
[
|
|
"BEGIN"
|
|
"END"
|
|
"BEGINFILE"
|
|
"ENDFILE"
|
|
] @label
|
|
|
|
(binary_exp [
|
|
"^"
|
|
"**"
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"+"
|
|
"-"
|
|
"<"
|
|
">"
|
|
"<="
|
|
">="
|
|
"=="
|
|
"!="
|
|
"~"
|
|
"!~"
|
|
"in"
|
|
"&&"
|
|
"||"
|
|
] @operator)
|
|
|
|
(unary_exp [
|
|
"!"
|
|
"+"
|
|
"-"
|
|
] @operator)
|
|
|
|
(assignment_exp [
|
|
"="
|
|
"+="
|
|
"-="
|
|
"*="
|
|
"/="
|
|
"%="
|
|
"^="
|
|
] @operator)
|
|
|
|
(ternary_exp [
|
|
"?"
|
|
":"
|
|
] @keyword.conditional.ternary)
|
|
|
|
(update_exp [
|
|
"++"
|
|
"--"
|
|
] @operator)
|
|
|
|
(redirected_io_statement [
|
|
">"
|
|
">>"
|
|
] @operator)
|
|
|
|
(piped_io_statement [
|
|
"|"
|
|
"|&"
|
|
] @operator)
|
|
|
|
(piped_io_exp [
|
|
"|"
|
|
"|&"
|
|
] @operator)
|
|
|
|
(field_ref "$" @punctuation.delimiter)
|
|
|
|
(regex "/" @punctuation.delimiter)
|
|
(regex_constant "@" @punctuation.delimiter)
|
|
|
|
[ ";" "," ] @punctuation.delimiter
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|