mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-06 05:20:00 -04:00
15de22a2e1
Usage: - nvim -l scripts/format-queries.lua /path/to/file.scm - nvim -l scripts/format-queries.lua /path/to/dir fixup: add `format-ignore` directive to query/highlights.scm
53 lines
1.3 KiB
Scheme
53 lines
1.3 KiB
Scheme
(string) @string
|
|
(escape_sequence) @string.escape
|
|
(capture (identifier) @type)
|
|
(anonymous_node (identifier) @string)
|
|
(predicate name: (identifier) @function.call)
|
|
(named_node name: (identifier) @variable)
|
|
(field_definition name: (identifier) @property)
|
|
(negated_field "!" @operator (identifier) @property)
|
|
(comment) @comment @spell
|
|
|
|
(quantifier) @operator
|
|
(predicate_type) @punctuation.special
|
|
|
|
"." @operator
|
|
|
|
[
|
|
"["
|
|
"]"
|
|
"("
|
|
")"
|
|
] @punctuation.bracket
|
|
|
|
":" @punctuation.delimiter
|
|
["@" "#"] @punctuation.special
|
|
"_" @constant
|
|
|
|
((parameters (identifier) @number)
|
|
(#match? @number "^[-+]?[0-9]+(.[0-9]+)?$"))
|
|
|
|
((program . (comment)* . (comment) @keyword.import)
|
|
(#lua-match? @keyword.import "^;+ *inherits *:"))
|
|
|
|
((program . (comment)* . (comment) @keyword.directive)
|
|
(#lua-match? @keyword.directive "^;+ *extends *$"))
|
|
|
|
((comment) @keyword.directive
|
|
(#lua-match? @keyword.directive "^;+%s*format%-ignore%s*$"))
|
|
|
|
((predicate
|
|
name: (identifier) @_name
|
|
parameters: (parameters (string "\"" @string "\"" @string) @string.regexp))
|
|
(#any-of? @_name
|
|
"match"
|
|
"not-match"
|
|
"vim-match"
|
|
"not-vim-match"
|
|
"lua-match"
|
|
"not-lua-match"))
|
|
|
|
((predicate
|
|
name: (identifier) @_name
|
|
parameters: (parameters (string "\"" @string "\"" @string) @string.regexp . (string) .))
|
|
(#any-of? @_name "gsub" "not-gsub"))
|