mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-01 19:17:02 -04:00
1ae9b0e455
Problem: Sharing highlight queries with upstream tree-sitter and
Helix is difficult.
Solution: Where reasonable, use capture names in tree-sitter's standard
list or Helix's Atom-style hierarchy.
Specifically:
* tree-sitter "standard capture names"
(3f44b89685/highlight/src/lib.rs (L20-L72)):
- `@parameter` -> `@variable.parameter`
- `@field` -> `@variable.member`
- `@namespace` -> `@module`
- `@float` -> `@number.float`
- `@symbol` -> `@string.special.symbol`
- `@string.regex` -> `@string.regexp`
- `@text.*` -> `@markup.*` (`strong`, `italic`, `link`, `strikethrough`; with exceptions; see below)
- `@text.title` -> `@markup.heading`
- `@text.literal` -> `@markup.raw`
- `@text.reference` -> `@markup.link`
- `@text.uri` -> `@markup.link.url` (in markup links)
- `@string.special` -> `@markup.link.label` (non-url links)
- `@punctuation.special` -> `@markup.list` (markdown lists only; move subitems from `@text.todo`)
* Helix captures
(https://docs.helix-editor.com/master/themes.html#syntax-highlighting):
- `@method` -> `@function.method`
- `@method.call` -> `@function.method.call`
- `@text.{todo,warning,note,danger}` -> `@comment.{error,warning,hint,info,todo}`
- `@text.diff.{add,delete,}` -> `@diff.{plus,minus,delta}`
- `@text.uri` -> `@string.special.url` (outside markup)
- `@preproc` -> `@keyword.directive`
- `@define` -> `@keyword.directive`(`.define`?)
- `@storageclass` -> `@keyword.storage`
- `@conditional` -> `@keyword.conditional`
- `@debug` -> `@keyword.debug`
- `@exception` -> `@keyword.exception`
- `@include` -> `@keyword.import`
- `@repeat` -> `@keyword.repeat`
* cleanup
- remove some redundant `@conceal` (but still allow it for conceal-only patterns)
- remove obsolete `@error` (syntax linting is out of scope for this repo)
- sort, cleanup capture list in `CONTRIBUTING.md`
55 lines
1.2 KiB
Scheme
55 lines
1.2 KiB
Scheme
; inherits: ecma,jsx
|
|
|
|
;;; Parameters
|
|
(formal_parameters (identifier) @variable.parameter)
|
|
|
|
(formal_parameters
|
|
(rest_pattern
|
|
(identifier) @variable.parameter))
|
|
|
|
;; ({ a }) => null
|
|
(formal_parameters
|
|
(object_pattern
|
|
(shorthand_property_identifier_pattern) @variable.parameter))
|
|
|
|
;; ({ a = b }) => null
|
|
(formal_parameters
|
|
(object_pattern
|
|
(object_assignment_pattern
|
|
(shorthand_property_identifier_pattern) @variable.parameter)))
|
|
|
|
;; ({ a: b }) => null
|
|
(formal_parameters
|
|
(object_pattern
|
|
(pair_pattern
|
|
value: (identifier) @variable.parameter)))
|
|
|
|
;; ([ a ]) => null
|
|
(formal_parameters
|
|
(array_pattern
|
|
(identifier) @variable.parameter))
|
|
|
|
;; ({ a } = { a }) => null
|
|
(formal_parameters
|
|
(assignment_pattern
|
|
(object_pattern
|
|
(shorthand_property_identifier_pattern) @variable.parameter)))
|
|
|
|
;; ({ a = b } = { a }) => null
|
|
(formal_parameters
|
|
(assignment_pattern
|
|
(object_pattern
|
|
(object_assignment_pattern
|
|
(shorthand_property_identifier_pattern) @variable.parameter))))
|
|
|
|
;; a => null
|
|
(arrow_function
|
|
parameter: (identifier) @variable.parameter)
|
|
|
|
;; optional parameters
|
|
(formal_parameters
|
|
(assignment_pattern
|
|
left: (identifier) @variable.parameter))
|
|
|
|
;; punctuation
|
|
(optional_chain) @punctuation.delimiter
|