mirror of
https://github.com/nvim-treesitter/nvim-treesitter.git
synced 2026-07-10 07:20:06 -04:00
652da0b40f
Previously java was configured to use doxygen parser for documentation comments, but javadocs are not doxygen. Inline tags have a different syntax, block tags are not recognized, and doxygen creates a lot of errors during highlighting. Add parser for javadoc comments, with queries for highlights and injections.
30 lines
827 B
Scheme
30 lines
827 B
Scheme
; @value tags without double-quotes
|
|
((bare_format_string) @injection.content
|
|
(#set! injection.language "printf"))
|
|
|
|
; @value tags with double quotes
|
|
((literal_format_string) @injection.content
|
|
(#offset! @injection.content 0 1 0 -1)
|
|
(#set! injection.language "printf"))
|
|
|
|
; injected code snippets
|
|
((snippet_tag
|
|
(attributes
|
|
(attribute
|
|
name: (identifier) @_attribute_key
|
|
value: (attribute_value
|
|
[
|
|
(identifier) @injection.language
|
|
(string_literal
|
|
(quoted_value) @injection.language)
|
|
])))
|
|
body: (description) @injection.content)
|
|
(#eq? @_attribute_key "lang"))
|
|
|
|
; html content
|
|
((description) @injection.content
|
|
(#set! injection.language "html"))
|
|
|
|
; markdown content
|
|
((markdown_description) @injection.content
|
|
(#set! injection.language "markdown_inline"))
|