benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-16 18:30:06 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions

feat: add powershell language

Browse source
This commit is contained in:
Andrey Chalkin 2024-07-22 23:14:45 +02:00 • committed by GitHub
parent 4ee9f12ff5
commit c5b3560306
No known key found for this signature in database
GPG key ID: B5690EEEBB952194
8 changed files with 500 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

27
queries/powershell/injections.scm Normal file
View file

@ -0,0 +1,27 @@
; comments and block-comments
((comment) @injection.content
(#set! injection.language "comment"))
; dynamic invocation like & "$env:ChocolateyInstall\bin\choco.exe"
(command
(command_invokation_operator) @_operator
(command_name_expr
(string_literal) @injection.content)
(#eq? @_operator "&")
(#set! injection.language "powershell")
(#offset! @injection.content 0 1 0 -1)
(#set! injection.include-children))
; switch -regex
(switch_statement
(switch_parameters
(switch_parameter) @_parameter)
(switch_body
(switch_clauses
(switch_clause
(switch_clause_condition
(string_literal) @injection.content))))
(#eq? @_parameter "-regex")
(#set! injection.language "regex")
(#offset! @injection.content 0 1 0 -1)
(#set! injection.include-children))