feat: add chatito

README.md

@@ -184,6 +184,7 @@ We are looking for maintainers to add more parsers and to write query files for
 - [x] [c](https://github.com/tree-sitter/tree-sitter-c) (maintained by @vigoux)
 - [x] [c_sharp](https://github.com/tree-sitter/tree-sitter-c-sharp) (maintained by @Luxed)
 - [x] [capnp](https://github.com/amaanq/tree-sitter-capnp) (maintained by @amaanq)
+- [x] [chatito](https://github.com/ObserverOfTime/tree-sitter-chatito) (maintained by @ObserverOfTime)
 - [x] [clojure](https://github.com/sogaiu/tree-sitter-clojure) (maintained by @sogaiu)
 - [x] [cmake](https://github.com/uyha/tree-sitter-cmake) (maintained by @uyha)
 - [x] [comment](https://github.com/stsewd/tree-sitter-comment) (maintained by @stsewd)

lockfile.json

@@ -35,6 +35,9 @@
   "capnp": {
     "revision": "740c757b9585925b1ed27cef7d61ac39b7824304"
   },
+  "chatito": {
+    "revision": "3baf22e7e507cedf15d1dbc03df8afa50a625586"
+  },
   "clojure": {
     "revision": "262d6d60f39f0f77b3dd08da8ec895bd5a044416"
   },

lua/nvim-treesitter/parsers.lua

@@ -168,6 +168,14 @@ list.capnp = {
   maintainers = { "@amaanq" },
 }
 
+list.chatito = {
+  install_info = {
+    url = "https://github.com/ObserverOfTime/tree-sitter-chatito",
+    files = { "src/parser.c" },
+  },
+  maintainers = { "@ObserverOfTime" },
+}
+
 list.clojure = {
   install_info = {
     url = "https://github.com/sogaiu/tree-sitter-clojure",

queries/chatito/folds.scm

@@ -0,0 +1,5 @@
+[
+ (intent_def)
+ (slot_def)
+ (alias_def)
+] @fold

queries/chatito/highlights.scm

@@ -0,0 +1,54 @@
+;; Punctuation
+
+[
+ "%["
+ "@["
+ "~["
+ "*["
+ "]"
+ "("
+ ")"
+] @punctuation.bracket
+
+[":" ","] @punctuation.delimiter
+
+(["\"" "'"] @punctuation.special @conceal
+            (#set! conceal ""))
+
+["%" "?" "#"] @character.special
+
+;; Entities
+
+(intent) @namespace
+
+(slot) @type
+
+(variation) @type.qualifier
+
+(alias) @property
+
+(number) @number
+
+(argument
+  key: (string) @label
+  value: (string) @string)
+
+(escape) @string.escape
+
+;; Import
+
+"import" @include
+
+(file) @string.special
+
+;; Text
+
+(word) @text @spell
+
+;; Comment
+
+(comment) @comment @spell
+
+;; Error
+
+(ERROR) @error

queries/chatito/indents.scm

@@ -0,0 +1,7 @@
+[
+ (intent_def)
+ (slot_def)
+ (alias_def)
+] @indent
+
+(ERROR "]") @indent

queries/chatito/injections.scm

@@ -0,0 +1 @@
+(comment) @comment

queries/chatito/locals.scm

@@ -0,0 +1,10 @@
+;; Definitions
+
+(intent_def (intent) @definition)
+(slot_def (slot) @definition)
+(alias_def (alias) @definition)
+
+;; References
+
+(slot_ref (slot) @reference)
+(alias_ref (alias) @reference)