Add HEEx language support, add missing commentstrings

after/ftplugin/elixir.vim

@@ -0,0 +1 @@
+setlocal commentstring=#\ %s

after/ftplugin/heex.vim

@@ -0,0 +1 @@
+setlocal commentstring=<%#\ %s\ %>

after/ftplugin/surface.vim

@@ -0,0 +1 @@
+setlocal commentstring={!--\ %s\ --}

ftdetect/elixir.vim

@@ -1,2 +1,2 @@
 au BufRead,BufNewFile *.ex,*.exs,mix.lock set filetype=elixir
-au BufRead,BufNewFile *.eex,*.leex,*.heex set filetype=eelixir
+au BufRead,BufNewFile *.eex,*.leex set filetype=eelixir

ftdetect/heex.vim

@@ -0,0 +1 @@
+au BufRead,BufNewFile *.heex set filetype=heex

lua/nvim-treesitter/parsers.lua

@@ -271,6 +271,16 @@ list.surface = {
   maintainers = { "@connorlay" },
 }
 
+list.heex = {
+  install_info = {
+    url = "https://github.com/connorlay/tree-sitter-heex",
+    files = { "src/parser.c" },
+    branch = "main",
+  },
+  filetype = "heex",
+  maintainers = { "@connorlay" },
+}
+
 list.ocaml = {
   install_info = {
     url = "https://github.com/tree-sitter/tree-sitter-ocaml",

queries/elixir/injections.scm

@@ -13,3 +13,8 @@
    (sigil_start) @_start
    (sigil_content) @surface)
  (#eq? @_start "~F\"\"\""))
+
+((sigil
+   (sigil_start) @_start
+   (sigil_content) @heex)
+ (#eq? @_start "~H\"\"\""))

queries/heex/folds.scm

@@ -0,0 +1,5 @@
+; HEEx folds similar to HTML
+[
+  (tag)
+  (component)
+] @fold

queries/heex/highlights.scm

@@ -0,0 +1,35 @@
+; HEEx text is highlighted as such
+(text) @text
+
+; HEEx has two types of comments, both are highlighted as such
+(comment) @comment
+
+; HEEx attributes are highlighted as HTML attributes
+(attribute_name) @tag.attribute
+
+; Attributes are highlighted as strings
+(quoted_attribute_value) @string
+
+; HEEx supports HTML tags and are highlighted as such
+[
+  "<"
+  ">"
+  "</"
+  "/>"
+  "<%"
+  "<%="
+  "<%%="
+  "<%#"
+  "%>"
+  "{"
+  "}"
+] @tag.delimiter
+
+; HEEx tags are highlighted as HTML
+(tag_name) @tag
+
+; HEEx components are highlighted as types (Elixir modules)
+(component_name) @type
+
+; HEEx operators
+["="] @operator

queries/heex/indents.scm

@@ -0,0 +1,11 @@
+; HEEx  indents like HTML
+[
+  (component)
+  (tag)
+] @indent
+
+; Dedent at the end of each tag
+[
+  (end_tag)
+  (end_component)
+] @branch

queries/heex/injections.scm

@@ -0,0 +1,7 @@
+; Directives are combined to support do blocks
+(directive (expression_value) @elixir @combined)
+
+; Expressions are not combined, as they exist separately from do blocks
+(expression (expression_value) @elixir)
+
+(comment) @comment

queries/surface/folds.scm

@@ -1,5 +1,6 @@
 ; Surface folds similar to HTML and includes blocks
 [
   (tag)
+  (component)
   (block)
 ] @fold

queries/surface/highlights.scm

@@ -19,12 +19,12 @@
 
 ; Surface supports HTML tags and are highlighted as such
 [
-  (start_tag)
-  (end_tag)
-  (self_closing_tag)
-  (start_component)
-  (end_component)
-  (self_closing_component)
+  "<"
+  ">"
+  "</"
+  "/>"
+  "{"
+  "}"
 ] @tag.delimiter
 
 ; Expressions are similar to string interpolation, and are highloghted as such

queries/surface/indents.scm

@@ -1,5 +1,6 @@
 ; Surface indents like HTML, with the addition of blocks 
 [
+  (component)
   (tag)
   (block)
 ] @indent
@@ -7,6 +8,7 @@
 ; Dedent at the end of each tag, as well as a subblock
 [
   (end_tag)
+  (end_component)
   (end_block)
   (subblock)
 ] @branch