feat: add gotemplate and helm parser support

queries/gotmpl/highlights.scm

@@ -0,0 +1,108 @@
+; Identifiers
+[
+  (field)
+  (field_identifier)
+] @variable.member
+
+(variable) @variable
+
+; Function calls
+(function_call
+  function: (identifier) @function)
+
+(method_call
+  method:
+    (selector_expression
+      field: (field_identifier) @function))
+
+; Builtin functions
+(function_call
+  function: (identifier) @function.builtin
+  (#any-of? @function.builtin
+    "and" "call" "html" "index" "slice" "js" "len" "not" "or" "print" "printf" "println" "urlquery"
+    "eq" "ne" "lt" "ge" "gt" "ge"))
+
+; Operators
+[
+  "|"
+  ":="
+] @operator
+
+; Delimiters
+[
+  "."
+  ","
+] @punctuation.delimiter
+
+[
+  "{{"
+  "}}"
+  "{{-"
+  "-}}"
+  ")"
+  "("
+] @punctuation.bracket
+
+; Actions
+(if_action
+  [
+    "if"
+    "else"
+    "else if"
+    "end"
+  ] @keyword.conditional)
+
+(range_action
+  [
+    "range"
+    "else"
+    "end"
+  ] @keyword.repeat)
+
+(template_action
+  "template" @function.builtin)
+
+(block_action
+  [
+    "block"
+    "end"
+  ] @keyword.directive)
+
+(define_action
+  [
+    "define"
+    "end"
+  ] @keyword.directive.define)
+
+(with_action
+  [
+    "with"
+    "else"
+    "end"
+  ] @keyword.conditional)
+
+; Literals
+[
+  (interpreted_string_literal)
+  (raw_string_literal)
+] @string
+
+(rune_literal) @string.special.symbol
+
+(escape_sequence) @string.escape
+
+[
+  (int_literal)
+  (imaginary_literal)
+] @number
+
+(float_literal) @number.float
+
+[
+  (true)
+  (false)
+] @boolean
+
+(nil) @constant.builtin
+
+(comment) @comment @spell

queries/gotmpl/injections.scm

@@ -0,0 +1,34 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))
+
+; {{"put" | printf "%s%s" "out" | printf "%q"}}
+(function_call
+  function: (identifier) @_function
+  arguments:
+    (argument_list
+      .
+      (interpreted_string_literal) @injection.content)
+  (#eq? @_function "printf")
+  (#set! injection.language "printf"))
+
+; {{ js "var a = 1 + 1" }}
+(function_call
+  function: (identifier) @_function
+  arguments:
+    (argument_list
+      .
+      (interpreted_string_literal) @injection.content)
+  (#eq? @_function "js")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.language "javascript"))
+
+; {{ html "<h1>hello</h1>" }}
+(function_call
+  function: (identifier) @_function
+  arguments:
+    (argument_list
+      .
+      (interpreted_string_literal) @injection.content)
+  (#eq? @_function "html")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.language "html"))

queries/helm/highlights.scm

@@ -0,0 +1,46 @@
+; inherits: gotmpl
+
+; Builtin functions
+(function_call
+  function: (identifier) @function.builtin
+  (#any-of? @function.builtin
+    "and" "or" "not" "eq" "ne" "lt" "le" "gt" "ge" "default" "required" "empty" "fail" "coalesce"
+    "ternary" "print" "println" "printf" "trim" "trimAll" "trimPrefix" "trimSuffix" "lower" "upper"
+    "title" "untitle" "repeat" "substr" "nospace" "trunc" "abbrev" "abbrevboth" "initials"
+    "randAlphaNum" "randAlpha" "randNumeric" "randAscii" "wrap" "wrapWith" "contains" "hasPrefix"
+    "hasSuffix" "quote" "squote" "cat" "indent" "nindent" "replace" "plural" "snakecase" "camelcase"
+    "kebabcase" "swapcase" "shuffle" "toStrings" "toDecimal" "toJson" "mustToJson" "toPrettyJson"
+    "mustToPrettyJson" "toRawJson" "mustToRawJson" "fromYaml" "fromJson" "fromJsonArray"
+    "fromYamlArray" "toYaml" "regexMatch" "mustRegexMatch" "regexFindAll" "mustRegexFinDall"
+    "regexFind" "mustRegexFind" "regexReplaceAll" "mustRegexReplaceAll" "regexReplaceAllLiteral"
+    "mustRegexReplaceAllLiteral" "regexSplit" "mustRegexSplit" "sha1sum" "sha256sum" "adler32sum"
+    "htpasswd" "derivePassword" "genPrivateKey" "buildCustomCert" "genCA" "genSelfSignedCert"
+    "genSignedCert" "encryptAES" "decryptAES" "now" "ago" "date" "dateInZone" "duration"
+    "durationRound" "unixEpoch" "dateModify" "mustDateModify" "htmlDate" "htmlDateInZone" "toDate"
+    "mustToDate" "dict" "get" "set" "unset" "hasKey" "pluck" "dig" "merge" "mustMerge"
+    "mergeOverwrite" "mustMergeOverwrite" "keys" "pick" "omit" "values" "deepCopy" "mustDeepCopy"
+    "b64enc" "b64dec" "b32enc" "b32dec" "list" "first" "mustFirst" "rest" "mustRest" "last"
+    "mustLast" "initial" "mustInitial" "append" "mustAppend" "prepend" "mustPrepend" "concat"
+    "reverse" "mustReverse" "uniq" "mustUniq" "without" "mustWithout" "has" "mustHas" "compact"
+    "mustCompact" "index" "slice" "mustSlice" "until" "untilStep" "seq" "add" "add1" "sub" "div"
+    "mod" "mul" "max" "min" "len" "addf" "add1f" "subf" "divf" "mulf" "maxf" "minf" "floor" "ceil"
+    "round" "getHostByName" "base" "dir" "clean" "ext" "isAbs" "kindOf" "kindIs" "typeOf" "typeIs"
+    "typeIsLike" "deepequal" "semver" "semverCompare" "urlParse" "urlJoin" "urlquery" "lookup"
+    "include")
+  )
+
+; {{ .Values.test }}
+(selector_expression
+  operand:
+    (field
+      name: (identifier) @constant.builtin
+      (#any-of? @constant.builtin
+        "Values" "Chart" "Release" "Capabilities" "Files" "Subcharts" "Template"))
+  (field_identifier))
+
+; {{ $.Values.test }}
+(selector_expression
+  operand: (variable)
+  field: (field_identifier) @constant.builtin
+  (#any-of? @constant.builtin
+    "Values" "Chart" "Release" "Capabilities" "Files" "Subcharts" "Template"))

queries/helm/injections.scm

@@ -0,0 +1,39 @@
+; inherits: gotmpl
+
+((text) @injection.content
+  (#set! injection.language "yaml")
+  (#set! injection.combined))
+
+; {{ regexFind "[a-zA-Z][1-9]" "abcd1234" }}
+(function_call
+  function: (identifier) @_function
+  arguments:
+    (argument_list
+      .
+      (interpreted_string_literal) @injection.content)
+  (#any-of? @_function
+    "regexMatch" "mustRegexMatch" "regexFindAll" "mustRegexFinDall" "regexFind" "mustRegexFind"
+    "regexReplaceAll" "mustRegexReplaceAll" "regexReplaceAllLiteral" "mustRegexReplaceAllLiteral"
+    "regexSplit" "mustRegexSplit")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.language "regex"))
+
+(function_call
+  function: (identifier) @_function
+  arguments:
+    (argument_list
+      .
+      (interpreted_string_literal) @injection.content)
+  (#any-of? @_function "fromYaml" "fromYamlArray")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.language "yaml"))
+
+(function_call
+  function: (identifier) @_function
+  arguments:
+    (argument_list
+      .
+      (interpreted_string_literal) @injection.content)
+  (#any-of? @_function "fromJson" "fromJsonArray")
+  (#offset! @injection.content 0 1 0 -1)
+  (#set! injection.language "json"))