feat(caddy): add parser and queries (#7588)

---------

Co-authored-by: Christian Clason <c.clason@uni-graz.at>

queries/caddy/folds.scm

@@ -0,0 +1 @@
+(block) @fold

queries/caddy/highlights.scm

@@ -0,0 +1,55 @@
+(comment) @comment @spell
+
+[
+  (env)
+  (argv)
+  (block_variable)
+  (placeholder)
+] @constant
+
+(value) @variable
+
+(directive
+  (keyword) @attribute)
+
+(global_options
+  (option
+    (keyword) @attribute))
+
+(keyword) @keyword
+
+(boolean) @boolean
+
+(placeholder
+  [
+    "{"
+    "}"
+  ] @punctuation.special)
+
+(auto) @variable.builtin
+
+[
+  (string_literal)
+  (quoted_string_literal)
+  (address)
+] @string
+
+[
+  (matcher)
+  (route)
+  (snippet_name)
+] @string.special
+
+[
+  (numeric_literal)
+  (time)
+  (size)
+  (ip_literal)
+] @number
+
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+"," @punctuation.delimiter

queries/caddy/indents.scm

@@ -0,0 +1,8 @@
+(block) @indent.begin
+
+(block
+  "}" @indent.branch)
+
+(comment) @indent.auto
+
+(ERROR) @indent.auto

queries/caddy/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+  (#set! injection.language "comment"))