benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-01 19:17:02 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions

feat: more @string.regex highlights

Browse source
This commit is contained in:
Riley Bruins 2023-12-21 15:31:40 -08:00 • committed by Christian Clason
parent c4da794564
commit 92572c0dfd
3 changed files with 62 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

20
queries/lua/highlights.scm
View file

@ -247,3 +247,23 @@
(string) @string
(escape_sequence) @string.escape
; string.match("123", "%d+")
(function_call
(dot_index_expression
field: (identifier) @_method
(#any-of? @_method "find" "match" "gmatch" "gsub"))
arguments: (arguments
. (_)
.
(string
content: (string_content) @string.regex)))
;("123"):match("%d+")
(function_call
(method_index_expression
method: (identifier) @_method
(#any-of? @_method "find" "match" "gmatch" "gsub"))
arguments: (arguments
. (string
content: (string_content) @string.regex)))

26
queries/luau/highlights.scm
View file

@ -246,3 +246,29 @@
((comment) @comment.documentation
(#lua-match? @comment.documentation "^[-][-](%s?)@"))
; string.match("123", "%d+")
(function_call
(dot_index_expression
field: (identifier) @_method
(#any-of? @_method "find" "format" "match"))
arguments: (arguments (_) . (string content: _ @string.regex)))
(function_call
(dot_index_expression
field: (identifier) @_method
(#any-of? @_method "gmatch" "gsub"))
arguments: (arguments (_) (string content: _ @string.regex)))
; ("123"):match("%d+")
(function_call
(method_index_expression
method: (identifier) @_method
(#any-of? @_method "find" "format" "match"))
arguments: (arguments . (string content: _ @string.regex)))
(function_call
(method_index_expression
method: (identifier) @_method
(#any-of? @_method "gmatch" "gsub"))
arguments: (arguments (string content: _ @string.regex)))

16
queries/query/highlights.scm
View file

@ -32,3 +32,19 @@
((program . (comment)* . (comment) @preproc)
(#lua-match? @preproc "^;+ *extends *$"))
((predicate
name: (identifier) @_name
parameters: (parameters (string "\"" @string "\"" @string) @string.regex))
(#any-of? @_name
"match"
"not-match"
"vim-match"
"not-vim-match"
"lua-match"
"not-lua-match"))
((predicate
name: (identifier) @_name
parameters: (parameters (string "\"" @string "\"" @string) @string.regex . (string) .))
(#any-of? @_name "gsub" "not-gsub"))