benbot/nvim-treesitter
1
0
Fork 0
mirror of https://github.com/nvim-treesitter/nvim-treesitter.git synced 2026-07-01 19:17:02 -04:00
Code Issues Projects Releases Packages Wiki Activity Actions

fix(kotlin): include regex in injections query

Browse source
This commit is contained in:
Sal Bakraa 2022-01-06 02:19:44 +03:00 • committed by Stephan Seitz
parent 5cfc96effe
commit 886ae5b87e
1 changed files with 31 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

31
queries/kotlin/injections.scm
View file

@ -1 +1,32 @@
(comment) @comment
; There are 3 ways to define a regex
; - "[abc]?".toRegex()
(call_expression
(navigation_expression
([(line_string_literal) (multi_line_string_literal)] @regex)
(navigation_suffix
((simple_identifier) @_function
(#eq? @_function "toRegex")))))
; - Regex("[abc]?")
(call_expression
((simple_identifier) @_function
(#eq? @_function "Regex"))
(call_suffix
(value_arguments
(value_argument
[ (line_string_literal) (multi_line_string_literal) ] @regex))))
; - Regex.fromLiteral("[abc]?")
(call_expression
(navigation_expression
((simple_identifier) @_class
(#eq? @_class "Regex"))
(navigation_suffix
((simple_identifier) @_function
(#eq? @_function "fromLiteral"))))
(call_suffix
(value_arguments
(value_argument
[ (line_string_literal) (multi_line_string_literal) ] @regex))))