chore(injections)!: update injection syntax to 0.9

Since 0.9, @lang syntax is still available as fallback but will soon be deprecated.
Because of that, new syntax should be adopted once 0.9 becomes the
baseline requirements for nvim-treesitter

- update health check
- update doc

queries/vim/injections.scm

@@ -1,18 +1,35 @@
-(lua_statement (script (body) @lua))
-(lua_statement (chunk) @lua)
-(ruby_statement (script (body) @ruby))
-(ruby_statement (chunk) @ruby)
-(python_statement (script (body) @python))
-(python_statement (chunk) @python)
+(lua_statement 
+  (script 
+    (body) @injection.content
+    (#set! injection.language "lua")))
+(lua_statement 
+  (chunk) @injection.content
+  (#set! injection.language "lua"))
+(ruby_statement 
+  (script 
+    (body) @injection.content 
+    (#set! injection.language "ruby")))
+(ruby_statement 
+  (chunk) @injection.content 
+  (#set! injection.language "ruby"))
+(python_statement 
+  (script 
+    (body) @injection.content 
+    (#set! injection.language "python")))
+(python_statement 
+  (chunk) @injection.content 
+  (#set! injection.language "python"))
 ;; If we support perl at some point...
 ;; (perl_statement (script (body) @perl))
 ;; (perl_statement (chunk) @perl)
 
-(autocmd_statement (pattern) @regex)
+(autocmd_statement 
+  (pattern) @injection.content 
+  (#set! injection.language "regex"))
 
 ((set_item
    option: (option_name) @_option
-   value: (set_value) @vim)
+   value: (set_value) @injection.content)
   (#any-of? @_option
     "includeexpr" "inex"
     "printexpr" "pexpr"
@@ -22,6 +39,8 @@
     "foldexpr" "fde"
     "diffexpr" "dex"
     "patchexpr" "pex"
-    "charconvert" "ccv"))
+    "charconvert" "ccv")
+  (#set! injection.language "vim"))
 
-(comment) @comment
+((comment) @injection.content 
+ (#set! injection.language "comment"))