chore(injections)!: update injection syntax to 0.9

Since 0.9, @lang syntax is still available as fallback but will soon be deprecated.
Because of that, new syntax should be adopted once 0.9 becomes the
baseline requirements for nvim-treesitter

- update health check
- update doc

queries/rust/injections.scm

@@ -1,34 +1,39 @@
 (macro_invocation
-  (token_tree) @rust)
+  (token_tree) @injection.content (#set! injection.language "rust"))
 
 (macro_definition
   (macro_rule
-    left: (token_tree_pattern) @rust
-    right: (token_tree) @rust))
+    left: (token_tree_pattern) @injection.content 
+    (#set! injection.language "rust")))
 
-[
+(macro_definition
+  (macro_rule
+    right: (token_tree) @injection.content
+    (#set! injection.language "rust")))
+
+([
   (line_comment)
   (block_comment)
-] @comment
+] @injection.content
+ (#set! injection.language "comment"))
 
-(
-  (macro_invocation
-    macro: ((identifier) @_html_def)
-    (token_tree) @html)
-
-    (#eq? @_html_def "html")
-)
+((macro_invocation
+   macro: ((identifier) @injection.language)
+   (token_tree) @injection.content)
+ (#eq? @injection.language "html"))
 
 (call_expression
   function: (scoped_identifier
     path: (identifier) @_regex (#eq? @_regex "Regex")
     name: (identifier) @_new (#eq? @_new "new"))
   arguments: (arguments
-    (raw_string_literal) @regex))
+    (raw_string_literal) @injection.content)
+    (#set! injection.language "regex"))
 
 (call_expression
   function: (scoped_identifier
     path: (scoped_identifier (identifier) @_regex (#eq? @_regex "Regex").)
     name: (identifier) @_new (#eq? @_new "new"))
   arguments: (arguments
-    (raw_string_literal) @regex))
+    (raw_string_literal) @injection.content)
+    (#set! injection.language "regex"))